Collect selected items from 2 galleries

[kpechal150]

Hi There, 

I have two galleries that each have check boxes for users to select items from Gallery 1 and Gallery 2. On Select of the button I want all ID's from Gallery 1 to be added to collection with all ID's from Gallery 2 duplicated for each row.

I tried this code but it only lists a single record as shown in the above picture. Whereas, I need it to list each of Gallery 1 ID's and duplicate Gallery 2 ID for each row.

ClearCollect(
    colLinkAll,
    {
        Gal1ID: Value(Gal1.Selected.Gal1ID),
        Gal2ID: Value(Gal2.Selected.Gal2ID),
        //RecordInfo for SQL db
        RecordCreatedBy: User().FullName,
        RecordCreatedDate: Today()
    }
);

I also tried this code but each column is in table format - 

Collect(
    colCombined,
    {Gal1ID: colGal1ID.Gal1ID}
);
Collect(
    colCombined,
    {Gal2ID: colGal2ID.Gal2ID}
)

These ID's are not related. There is nothing relating these 2 galleries. The end result collection is creating the relation between the 2 galleries once Patched to SQL and assigned an auto ID.

Any suggestions? Thank you!

[BCBuizer]

Hi @kpechal150 ,

The issue first issue is that you are referring Gal1.Selected which will only return a single item, whereas you seem to want to collect all items that are checked. The second issue is in the way you use the ClearCollect function which will also only created a single item but, if the first issue was fixed, with multiple values for Gal1ID.

To fix this, first you have to use a filter on all the items in the gallery to get the ones that are checked. Then you have to loop through those items to add an item to your collection for each of the checked items:

Clear(colLinkAll);

ForAll(
	Filter(
		Gal1.AllItems,
		CheckBox.Value
	),
	Collect(
		colLinkAll,
		{
			Gal1ID: Value(ThisRecord.Gal1ID),
			Gal2ID: Value(Gal2.Selected.Gal2ID),
			//RecordInfo for SQL db
			RecordCreatedBy: User().FullName,
			RecordCreatedDate: Today()
		}
	)
)

 In the above you may have to change 'CheckBox' with the actual name of the checkbox control in Gal1.

[BCBuizer · Accepted solution]

Hi @kpechal150 ,

And in case you wish to do the same to Gal2 as to Gal1, resulting in a total of 6 items created in case 3 items are checked in one gallery and 2 in the other, try the below formula:

ForAll(
	Filter(
		Gal1.AllItems,
		CheckBox.Value
	) As Gal1Items,
	ForAll(
		Filter(
			Gal2.AllItems,
			CheckBox.Value
		) As Gal2Items,
		Collect(
			colLinkAll,
			{
				Gal1ID: Value(Gal1Items.Gal1ID),
				Gal2ID: Value(Gal2Items.Gal2ID),
				//RecordInfo for SQL db
				RecordCreatedBy: User().FullName,
				RecordCreatedDate: Today()
			}
		)
	)
)

The same applies as before with replacing the names of the checkboxes in the galleries.

[kpechal150]

I spent 2 days working on this and you solved it in 30 seconds. I'm slightly annoyed (at myself) but very much appreciative. Thank you!!!

[BCBuizer]

Hi @kpechal150 ,

Very glad to have been of help. 

No need to be annoyed: Trust me I wasn't born with the ability to do this, so I hope you learned a bit from this for your future developments. 👍🏻