Collection exporting previous Items when submitting an "order"

[GeorgeMarkos]

Hi everyone,

I have created a shopping cart for clinical units so that they can order their supplies.

Thing is, when I try to export the data the entries from a previous order are exported.

The code I am using to create the shopping is below. 

Collect(
ShoppingCart,
{
Item: ThisItem.'Description ',
Subtotal: (Slider_3.Value),
Category: ThisItem.'Group Category ',
Unit: DDUnit.Selected.UNIT,
Date: Date.SelectedDate,
email: email.Text,
Name: Name.Text,
Comment: Comment.Text
}
)

The code I am using to export this collection to a SharePoint list (the name of the SharePoint list is "Neighborhood Supply Orders") is: 

ForAll(ShoppingCart,

Patch('Neighborhood Supply Order',Defaults('Neighborhood Supply Order'),
{
Item:Item,
Unit: Unit,
Category: Category,
Subtotal:Subtotal,
Name: Name,
email: email,
'Order Date':Date,
Comment:Comment
}
))

I am wondering why the previous entry is being exported and I have a suspicion is has to do with clear collect.

Any guidance on how to address this is most welcome, thank you!!!

[LaurensM]

Hi @GeorgeMarkos,

You may still store the old records after patching them to SharePoint. Would it be possible to clear the collection after the ForAll:

ForAll(...Your code...);
Clear(ShoppingCart)

After patching the records, your collection will be cleared and you can create a new shopping cart.

If this solves your question, would you be so kind as to accept it as a solution & give it a thumbs up.

Thanks!

[GeorgeMarkos]

Hi LaurensM, and thank you!!! for taking the time to respond

I do clear the cart after the patch, I just didn't include it it the previous thread.

This is the entire code that attempts to export to a SharePoint list, and shoots out an email message. it did work earlier today but went wonky and is bringing in the entry before the one being submitted.

Office365Outlook.SendEmail(email,"New Neighborhood Supply Order -" & DDUnit.Selected.UNIT & " - " & Date.SelectedDate,"There is a new supply order for that needs your attention for " & DDUnit.Selected.UNIT);

ForAll(ShoppingCart,

Patch('Neighborhood Supply Order',Defaults('Neighborhood Supply Order'),
{
Item:Item,
Unit: Unit,
Category: Category,
Subtotal:Subtotal,
Name: Name,
email: email,
'Order Date':Date,
Comment:Comment
}
))
;
Reset(DDUnit);
Clear(ShoppingCart)

and it still brings in the old values from the previous entry

[LaurensM]

@GeorgeMarkos,

When clearing the collection I would not expect older values to be patched to SharePoint. The issue may be occurring when you are saving the records to the ShoppingCart collection.

Where are you executing the Collect() code? Some column values are filled by using ThisItem (so I expect a gallery control or a Form), whereas other columns are filled by referring to controls. Would it be possible to give some more information on this functionality and on how you are able to tell that the values are actually from the previous entry?

Thanks!

[GeorgeMarkos]

The reason I know it comes from the previous entry so, a key piece of info that i forgot may be is that only three fields (of the eight) populate the record from a previous entry and the other four update correctly. What else can I share that will provide some insight?  and cant thank you enough for taking the time.

This is how i create the collection: 

Collect(
ShoppingCart,
{
Item: ThisItem.'Description ',
Subtotal: (Slider_3.Value),
Category: ThisItem.'Group Category ',
Unit: DDUnit.Selected.UNIT,
Date: Date.SelectedDate,
email: email.Text,
Name: Name.Text,
Comment: Comment.Text
}
);
Reset(Slider_3);
Reset(Searchbox);
Set(
VarShowSuccess,
true
)

and this is the export: 

Office365Outlook.SendEmail(email,"New Neighborhood Supply Order -" & DDUnit.Selected.UNIT & " - " & Date.SelectedDate,"There is a new supply order for that needs your attention for" & DDUnit.Selected.UNIT);

ForAll(ShoppingCart,

Patch('Neighborhood Supply Order',Defaults('Neighborhood Supply Order'),
{
Item:Item,
Unit: Unit,
Category: Category,
Subtotal:Subtotal,
Name: Name,
email: email,
'Order Date':Date,
Comment:Comment
}
))
;
Reset(DDUnit);
Clear(ShoppingCart)

Really can't thank you enough!

[LaurensM]

@GeorgeMarkos,

Thank you for the additional information. Which particular fields still contain the old record values? It may be related to the way we reference this in the Collect() function.

Should the control containing the Collect code be within a Gallery try:

//select parent first
Select(Parent);
//Save to ShoppingCart
Collect(
    ShoppingCart,
    {
        //Columns not referencing ThisItem see comment under this code block
        Item: ThisItem.'Description ',
        Subtotal: (Slider_3.Value),
        Category: ThisItem.'Group Category ',
        Unit: DDUnit.Selected.UNIT,
        Date: Date.SelectedDate,
        email: email.Text,
        Name: Name.Text,
        Comment: Comment.Text
    }
);
Reset(Slider_3);
Reset(Searchbox);
Set(
VarShowSuccess,
true
)

For me it is not fully clear why we are referencing both controls and ThisItem. In case the columns are available within the Item, use ThisItem.ColumnName instead of referring to a control. (e.g. Name.Text -> ThisItem.Name)

When referencing controls outside of the gallery, make sure the values do not still contain the previous values.

I hope this helps!

[GeorgeMarkos]

I will give it a shot tomorrow in the am, just got swamped with other work. Thanks LaurensM, 

[GeorgeMarkos]

another piece of info that may be helpful. The last three fields, Name, Comment, and email are entered on a page after the page that sets up the collection, so they have yet to be entered. Now that I think about it, that is probably why it is capturing the previous entry because the current entry has yet to be filled in. How does one get around that? Create another collection i guess and integrate the two?

[LaurensM]

@GeorgeMarkos,

Are Name, Email and Date shared accross all ShoppingCart records? If so you don't need to collect them, you could simply reference those within your ForAll:

Patch(
    'Neighborhood Supply Order',
    //Using ForAll as a Patch input is faster than using ForAll as a loop
    ForAll(
        ShoppingCart,
        {
            Item:Item,
            Unit: Unit,
            Category: Category,
            Subtotal:Subtotal,
            'Order Date':Date,
            //Using references to the controls
            Name: Name.Text,
            email: email.Text,
            Comment: Comment.Text
        }
    )
);
Reset(DDUnit);
Clear(ShoppingCart)

Feel free to respond tomorrow or at another time that suits you best. 😊 There may be a delay in my response due to my availability at that time - in this case feel free to tag other Super Users or Community Members for a faster response. (Write @ to tag people in your message)

I hope this helps!