Dropdown Box with words found in a collection

[Fernanda]

Hey

I am building an app that works offline, and it has a Pen Input for signatures. So far, saving the record to a photo collection works perfectly fine. 

The icon in the middle saves my photo with the following code. TextInput3_8 is "Nombre Firmante" where the name of who is signing goes.

Set(varNombreFirma;
TextInput3_8.Text & "-" &varPlanta & "-" & VarQuimico
)
;;
Collect(colFotos;
{
    DisplayName: varNombreFirma & ".jpg";
    Id: varNombreFirma & ".jpg";
    Value: PenInput1.Image;
    Timestamp: Now()
} );;
SaveData(colFotos;"ColeccionFotos");;
Reset(PenInput1);;Reset(TextInput3_8)

 This way, my signature is saved with the name of the person, the location (varPlanta) and the material it is asign to.

And what I want to do, is on the dropdown box "Firmas Guardadas", I want to list the signatures saved and show only the name of who signed

Example:

Location is PTAP Pisagua, so only names: Fernanda, Jose and Pablo should show on my dropdown. For the same location, I have several materials, and I want to bring back the first time one of these people sign so I can call it back and save it again with another name as a duplicate.

For other locations selected, people will change.

So, when the existing signature is selected, pen input will switch to an image and save again with the same button (formula must be updated accordingly)

I have been trying with lookup in a distinct formula, but I can't make it work.

Tried with a variable, but it keeps giving me errors..

Do you have any other ideas???

[RusselThomas]

Hi @Fernanda ,

Am I correct in saying you want to filter the data by location, then by distinct name?  

When I look at the savedata collection, the only place you're saving this info is concatentated into the displayname and id fields of the record.  If you want to make your life easier, I'd suggest adding separate columns to contain the data....

Set(varNombreFirma;
TextInput3_8.Text & "-" &varPlanta & "-" & VarQuimico
)
;;
Collect(colFotos;
{
    DisplayName: varNombreFirma & ".jpg";
    Id: varNombreFirma & ".jpg";
    Value: PenInput1.Image;
    Timestamp: Now();
    Signatory: TextInput3_8.Text;
    Location: varPlanta;
    Material: VarQuimico
} );;
SaveData(colFotos;"ColeccionFotos");;
Reset(PenInput1);;Reset(TextInput3_8)

- this would make it easier to filter on the collection later using these fields.

If you can't or would prefer not to do this, you can still use an "in" function to search for a location match inside the displayname based on a dropdown value.

you can then decide where and how you want to calculate the Name value for each row.  This would depend on how you're planning on showing the info - so if it's in a gallery, you can set the gallery Items: property to;

Filter(colFotos, locationDropdown.Selected.Value in DisplayName)

Then you can add a label to the gallery and depending on what part of the displayname you want it to display, set it to;

With({filename: First(Split(ThisItem.DisplayName,".jpg")).Result},
    With({splitValues: Split(filename, "-")},
        Index(splitValues, 1).Result   //first part which contains the name
        //Index(splitValues, 2).Result //second part contains the location
        //Index(splitValues, 3).Result //third part contains the material
    )
)

That will give you all the signature entries with that name for that location in a gallery.

If you only wanted a name dropdown containing distinct names instead, you can add a dropdown and set its Items: property to;

Distinct(
    AddColumns(Filter(colFotos, locationDropdown.Selected.Value in DisplayName), "Name", 
        With({filename: First(Split(DisplayName,".jpg")).Result},
            With({splitValues: Split(filename, "-")},
                Index(splitValues, 1).Result   //first part which contains the name
                //Index(splitValues, 2).Result //second part contains the location
                //Index(splitValues, 3).Result //third part contains the material
            )
        )
    ), Name)

and set the Dropdown Value: selector to "Result"

Hope this helps,

RT

[Fernanda]

Hello!

Thank you for your idea!

I had no choice but to add new columns, precisely Location and Signatory, but my formulas were a bit simpler (Still getting used to Powerapps and some formulas are quite complicated for me to understand).

What I also did, was adding an IF formula for visible property, to show the saved signature and use it to sign a new document and re-save it with a different chemical (with an IF formula)

my saving image formula

If(IsBlank(Dropdown1.Selected.Result);   
Set(varNombreFirma;
TextInput3_8.Text & "-" &varPlanta & "-" & VarQuimico
)
;;
Collect(colFotos;
{
    DisplayName: varNombreFirma & ".jpg";
    Id: varNombreFirma & ".jpg";
    Value: PenInput1.Image;
    Timestamp: Now();
    Planta: varPlanta;
    Firmante: TextInput3_8.Text
} );;
SaveData(colFotos;"ColeccionFotos");;
Reset(PenInput1);;Reset(TextInput3_8);
Set(varNombreFirma2;
Dropdown1.Selected.Result & "-" &varPlanta & "-" & VarQuimico
)
;;
Collect(colFotos;
{
    DisplayName: varNombreFirma2 & ".jpg";
    Id: varNombreFirma2 & ".jpg";
    Value: Image1.Image;
    Timestamp: Now();
    Planta: varPlanta;
    Firmante: Dropdown1.Selected.Result
} );;
SaveData(colFotos;"ColeccionFotos");;
Reset(PenInput1);;Reset(TextInput3_8);;Reset(Dropdown1))

  my dropdown formula:

Distinct(Filter(colFotos; Planta = varPlanta);Firmante)

my image visible formula:

If(IsBlank(Dropdown1_1.Selected.Result);false;true)

 my design

so far, works pretty good