Load the data that's stored in a multiline textbox into a gallery when opening the form

[Anonymous]

A section of a Power App that's linked to a SharePoint list I created is a  "repeating table" that I built using a Gallery and multiple text boxes.
I store this information in a multiline text field.

I simply do something like this in the Default property of the multiline text field:

Concat(
        Gallery1_1.AllItems,
        Concatenate(TextInput2_12.Text,";",TextInput2_6.Text,";",TextInput2_8.Text,";",TextInput2_9.Text,";",TextInput2_10.Text,";",TextInput2_13.Text,"|"
        )
    )

 And when I submit the form (SubmitForm(EditForm1)) it nicely saves the data into that multiline field.

What I'm struggling with is how to retrieve it back into the Gallery when I open the form again.

The way I add new items in the gallery is with a simple button that keeps adding a new row when I click on it.


This is what I have in the OnSelect property for that + button:

Collect(
    InformationCollection,
    {
        CSerialNumber: Text(Last(InformationCollection).CSerialNumber + 1),
        CUnit: "",
        CUnitOD: "",
        CUnitID: "",
        CUnitID2: "",
        CTest: ""
    }
)

How would I "un-concatenate" the multiline field back into this gallery?

[RandyHayes]

@Anonymous 

You will need to utilize the Split function to split the information by the semicolons that you used.

But, you mention the Default property - can you expand on this a little?  Are you using a Form?  Or are you talking about the Default of the TextInput control in your Gallery?

[Anonymous]

Yes, I was talking about the default property of the TextInput control but I realized that that's not a good idea. So instead I moved that logic when saving the form like so:

UpdateContext(  
    {  
 NewItemsString: Concat(
        Gallery1_1.AllItems,
        Concatenate(TextInput2_12.Text,";",TextInput2_6.Text,";",TextInput2_8.Text,";",TextInput2_9.Text,";",TextInput2_10.Text,";",TextInput2_13.Text,"|"
        )
    )
}
);
SubmitForm(EditForm1);

I then set the "Default" property of the multiline text field Data Card (which I have hidden from the view) to NewItemsString.

Thanks for the suggestion. I came up with this to load it back by setting the following in the OnVisible property of the Editscreen:

UpdateContext({NewItemsString: BrowseGallery1.Selected.'Multiline Information'});  
Clear(InformationCollection);  
Set(  
    Editstr,  
    BrowseGallery1.Selected.'Multiline Information'  
);  
Set(  
    Editstr,  
    Left(  
        Editstr,  
        Len(Editstr) - 1  
    )  
);  
ForAll(  
    Split(  
        Editstr,  
        "|"  
    ),  
    Collect(  
        AssetInformationCollection,  
        {  
            CSerialNumber: Text(  
                Last(  
                    FirstN(  
                        Split(  
                            Result,  
                            ";"  
                        ).Result,  
                        1  
                    ).Result  
                ).Result  
            ),  
            CUnit: Text(  
                Last(  
                    FirstN(  
                        Split(  
                            Result,  
                            ";"  
                        ).Result,  
                        2  
                    ).Result  
                ).Result  
            ),  
            CUnitOD: Text(  
                Last(  
                    FirstN(  
                        Split(  
                            Result,  
                            ";"  
                        ).Result,  
                        3  
                    ).Result  
                ).Result  
            ),  
            CUnitID: Text(  
                Last(  
                    FirstN(  
                        Split(  
                            Result,  
                            ";"  
                        ).Result,  
                        4  
                    ).Result  
                ).Result  
            ),
            CUnitID2: Text(  
                Last(  
                    FirstN(  
                        Split(  
                            Result,  
                            ";"  
                        ).Result,  
                        5  
                    ).Result  
                ).Result  
            ),
            CTest: Text(  
                Last(  
                    FirstN(  
                        Split(  
                            Result,  
                            ";"  
                        ).Result,  
                        6  
                    ).Result  
                ).Result  
            )  
        }  
    )  
)  

I'm almost there.

It appears that everything works as intended except that when opening a form that already has 1 row added, when I click on the + button to add a new item it starts the row count from 1 instead of 2 and if I click on the delete button it deletes both rows.

So it's almost like the + button is not seeing the rows that were loaded at the OnVisible step.

[RandyHayes · Accepted solution]

@Anonymous 

You might want to simplify your formula!

The following is equivalent to what you provided:

UpdateContext({NewItemsString: BrowseGallery1.Selected.'Multiline Information'});  

ClearCollect(  
    AssetInformationCollection,  
    ForAll(Split(Left(BrowseGallery1.Selected.'Multiline Information')-1, "|"),
    	With({_line: Split(Result, ";")},
          {  
           CSerialNumber: Last(FirstN(_line, 1).Result,
           CUnit: Last(FirstN(_line, 2).Result,
           CUnitOD: Last(FirstN(_line, 3).Result,
           CUnitID: Last(FirstN(_line, 4).Result,  
           CUnitID2: Last(FirstN(_line, 5).Result,
           CTest: Last(FirstN(_line, 6 ).Result
          }  
        )
    )  
)  

I'm not understanding though the full flow of your app or how things are getting loaded and where.  So, if you're having problems with the initial display of the items, expand a bit on your app and perhaps how it all interacts.

[Anonymous]

lol. That's quite the improvement on readability. Thank you!

ClearCollect(  
    AssetInformationCollection,  
    ForAll(Split(Left(BrowseGallery1.Selected.'Multiline Information',Len(BrowseGallery1.Selected.'Multiline Information')-1), "|"),
    	With({_line: Split(Result, ";")},
          {  
           CSerialNumber: Last(FirstN(_line, 1)).Result,
           CUnit: Last(FirstN(_line, 2)).Result,
           CUnitOD: Last(FirstN(_line, 3)).Result,
           CUnitID: Last(FirstN(_line, 4)).Result,  
           CUnitID2: Last(FirstN(_line, 5)).Result,
           CTest: Last(FirstN(_line, 6)).Result
          }  
        )
    )  
)  

Looks like you missed a few parentheses and a Len method in there but I figured it out. See above.
The issue with the rows was solved by changing the logic a bit depending if the form mode is in new or edit.

[RandyHayes]

@Anonymous 

Ah yes, have to type these things by hand, so no red underlines or errors.  It happens, glad you figured it out.

And, glad it is working well.

[Rushil]

Hi @Anonymous ,

I'm trying to perform something similar but facing issues. Firstly, I'm trying to show an incremented value by default similar to what you are doing with CSerialNumber. Also, what is 'Multiline Information' referred to in your case?
Can you please guide me how to proceed with this?

OnVisible - 

Collection Table

I'm not sure what to add in the default field of textInput for Time so as to have a default value.

[Anonymous]

Multiline information is the sharepoint field/column where I store the entire repeating table information. It's a multiline text field. So the 4 columns in your case would all be saved in this field like so:

Time1; PT1800 1; Change from Last Point 1; Avg Decay Rate 1|
Time2; PT1800 2; Change from Last Point 2; Avg Decay Rate 2|. etc.

So to answer your question. I don't see an increment number in your screenshot, so I assumed you don't have one yet. Or maybe it was CTime? Anyone I think you'll get the logic.

For OnVisible of the EditScreen:

UpdateContext({NewItemsString: ""});//clear the previous results
ClearCollect(collectItemInformation,[]);//clear previous results

ClearCollect(  
    collectItemInformation,  
    ForAll(Split(Left(BrowseGallery1.Selected.'Multiline Information',Len(BrowseGallery1.Selected.'Multiline Information')-1), "|"),
    	With({_line: Split(Result, ";")},
          { 
           CLineNumber: Last(FirstN(_line, 1)).Result,
           CTime: Last(FirstN(_line, 2)).Result,
           CPT: Last(FirstN(_line, 3)).Result,
           CChange: Last(FirstN(_line, 4)).Result,
           CAvg: Last(FirstN(_line, 5)).Result,  
          }  
        )
    )  
) 

For the + button on select:

Collect(
   collectItemInformation,
    {
           CLineNumber: Text(Last(collectItemInformation).CLineNumber + 1),
           CTime: "",
           CPT: "",
           CChange: "",
           CAvg: ""
    }
)

For the delete button OnSelect:

RemoveIf(
    collectItemInformation,
    CLineNumber = ThisItem.CLineNumber
)

For the Default property of the Gallery (leave blank)

For the Items property of the Gallery put: (this is to load the existing results when you open a form).

collectItemInformation

 For each field in the gallery (Your Ctime textbox Default should be ThisItem.Ctime, for your CPT textbox Default property it should be ThisItem.CPT, etc).

Finally for your Save button of the EditForm:
This will save all the results from the table into a variable. The substitutions is an extra trick I use to account for situations where the user actually enters a ; or | character which would break the repeating table.

UpdateContext(  
    {  
 NewItemsString: Concat(
        Gallery1.AllItems,
        Concatenate(
        Substitute(Substitute(CLineNumbertextbox.Text,";",":"),"|","/"),";",
        Substitute(Substitute(CTimetextbox.Text,";",":"),"|","/"),";",
        Substitute(Substitute(CPTtextbox.Text,";",":"),"|","/"),";",
        Substitute(Substitute(CChangetextbox.Text,";",":"),"|","/"),";",
        Substitute(Substitute(CAvg.Text,";",":"),"|","/"),";","|"
        )
    )
}
);

Lastly, the "Multiline Information" field datacard still needs to be somewhere on the form, you can set it's visible property to false but you need to set the Update property for that datacard to:

NewItemsString

Good luck!

[Rushil]

Hi @Anonymous ,

I really appreciate you taking out your time to help me out. This is the best explanation to this work and I will try implementing it as well.

One last thing to ask, I was trying to have 4 different multiline columns in SP list and then storing the data in them. For ex:

CTime        CPT       CChange

0                 1.2            - 

1                 1.1           0.1

2                 0.9           0.2

3                 0.75         0.15

These 3 columns will store there respective values in a Multifield format

Do you think this is the right way to do or should I use single multiline column to store everything together?

Thank a lot again for your help 🙂

[Anonymous]

If you believe it would be helpful to store it separately (each column of the repeating table in a separate column in the sharepoint list) then this will not work. To do that you'd have to have load a separate collection for each sharepoint column and then combine them into a single collection to be used for your gallery, lastly split it again at the end to be saved into each column. All the other steps are the same as the previous post I wrote.

So something like this:

On Visible of the form:

ClearCollect(CollectionCTime,Split(BrowseGallery1.Selected.'CTime', Char(10)));
ClearCollect(CollectionCPT,Split(BrowseGallery1.Selected.'CPT', Char(10)));
ClearCollect(CollectionCChange,Split(BrowseGallery1.Selected.'CChange', Char(10)));
ClearCollect(CollectionCAvg,Split(BrowseGallery1.Selected.'CAvg', Char(10)));

ClearCollect(AllCollection,[]); //this is preparing the big collection that will hold the above 4.

ForAll(Sequence(CountRows(CollectionCTime)),
Collect(AllCollection, { CTime: Last(FirstN(CollectionCTime, Value)).Result, Collect(AllCollection, { CPT: Last(FirstN(CollectionCPT, Value)).Result, CChange: Last(FirstN(CollectionCChange, Value)).Result, CAvg: Last(FirstN(CollectionCAvg, Value)).Result} ))


//make the field [CTime] required, or else it will not count  the nubmer of items correctly if users leave it blank

Your save button will be:

UpdateContext(  
    {  
 NewItemsStringCtime: Concat(
        Gallery1.AllItems,
        Concatenate(
        CTimetextbox.Text,Char(10)
        ))
   }
);
UpdateContext(  
    {  
 NewItemsStringCPT: Concat(
        Gallery1.AllItems,
        Concatenate(
        CPTtextbox.Text,Char(10)
        ))
   }
);

//repeat the above for the remaining two columns

Your Gallery Items will be: AllCollection and each textbox in the gallery will have the Default set to ThisItem.CTime (and the same for the other 3). The rest should be similar to the first solution. The + and remove button should be the same, and the Update button for each datacard (which can be hidden) should be set to it's respective NewItemsString variable.