Navigating through SharePoint list items in Power Apps: how to move to next item from an edit screen?

[DdVill]

Hello everyone,

I am currently developing an app to edit fields in a SharePoint list. The list contains a first column called "Parcela" in which each row represents a specific plot number, and the rest of the columns are titled after each month of the year.

(The plot numbering is not always consecutive, there are gaps such as for example 1233, 1234, 1241, 1242, 1245, 1300, etc.)

The app consists of a first screen called "BrowseScreen1", where there is a gallery called "BrowseGallery1". This gallery contains each plot number, and when you click on a button associated with it, it takes you to the "EditScreen1" screen, where the plot number appears as the title and a text field for editing the information for each month of the year.

What I want to do is implement a new icon on the "EditScreen1" screen that, when clicked, takes me to the same "EditScreen1" screen but for the next item in the list, which would be the next plot number.
I have tried many ways but nothing works for me. I have read many similar cases here but I am not able to apply the solutions to my specific case. I am very newb in this.

Can anyone please help me with this issue? Any guidance or suggestions would be greatly appreciated.

Thank you!

[LaurensM]

Hi @DdVill,

Let's take a look at a possible solution, step by step. It looks like you are using the app that is generated from data, which is good, but will need some extra steps to make this work.

(1) Let's change how the Form record is filled

Navigate to the BrowseScreen and select the Gallery control. Go to the OnSelect of this control and you will probably see the formula 'Navigate(DetailScreen1, ScreenTransition.None)'. Let's adjust this first:

Set(varSelectedRecord, ThisItem); Navigate(DetailScreen1, ScreenTransition.None)

Navigate to your DetailScreen & EditScreen and change the item property of the Forms. By default it will have code similar to 'BrowseGallery1.Selected'. Change this to varSelectedRecord

(don't forget to do this for both the detail and edit screen)

(2) Let's add the logic to the new icon on your edit screen

Here I expect the plot numbering column to be a number field. With the variables in place, we can now change the displayed item dynamically by overwriting the current value with a new one. This will be done by adding logic to the OnSelect of the icon. Below I will show you the general architecture of the code, please adjust the list / column names according to your specific case:

Set(
    varSelectedRecord,
    //Give me the first record
    First(
        //Sort by Plot number Ascending (closest value to our current number)
        Sort(
            //Only show me records with a higher plot number
            Filter(
                //Change listname
                LISTNAME,
                Parcela > varSelectedRecord.Parcela
            ),
            Parcela,
            Ascending
        )
    )
)

When clicking the icon, the Form item should change to the next plot number.

If this solves your question, would you be so kind as to accept it as a solution.

Thanks!

[DdVill]

Hello @LaurensM ,

First of all I want to thank you for taking your time to answer my inquiry. You explined it very good and I was able to understand everything and apply it to my case.

Unfortunately, the solution didn't work but I think it is close to work.
In my app, there is no DetailScreen. From BrowseScreen you can only go to EditScreen. I don't know if this is the problem.. so in the first step i wrote 

Set(varSelectedRecord; ThisItem)&&Navigate(EditForm1;ScreenTransition.None)

Take note that in my region the character "," is invalid so we use ";" between arguments. Also, we cannot use ";" to use a second action function, I wrote "&" or "&&". I don't know if that is the equivalence but it seems to work.

Then I changed the item property of EditForm1 to varSelectedRecord.

When editing OnSelect property of the icon I get the next warning:

Incidence
Delegation Warning. The "Filter" part of this formula may not work correctly on large data sets.
The data source may not be able to process the formula and return an incomplete data set. The application may not return correct results or may not behave correctly if the data set is incomplete.
Location

Icon3
.OnSelect

How to correct errors
If the dataset exceeds the limit of 500 records, but contains less than 2000, try resetting the limit.
Try simplifying the formula.
Try moving the data to another data source.
Article: Understanding Delegation in a Canvas Application
Blog: Data Row Limits for Delegation

 Edit: There are 5 elements on the list of plots which are text because they make reference to a certain areas. Could that also cause some problems? Because when I write Parcela on your code it gives me an error. Invalid argument:  expecting Number, Date, Time, DateTime.

Thank you again.

[LaurensM · Accepted solution]

Hi @DdVill,

You are using the ; syntax instead of , - this is dependent on the browser settings. This means that within my code all commas should be replaced with a semicolon and all semicolons with a double semicolon:

Set(varSelectedRecord; ThisItem);; Navigate(DetailScreen1; ScreenTransition.None)

Unfortunately due to the plot number being defined as a text field, we are receiving a delegation warning (number field would not have given a delegation warning). Should your list not become bigger than 2000 records, this is not something to worry about and you could just add the code below:

Set(
    varSelectedRecord;
    //Give me the first record
    First(
        //Sort by Plot number Ascending (closest value to our current number)
        Sort(
            //Only show me records with a higher plot number
            Filter(
                //Change listname
                LISTNAME;
                Value(Parcela) > Value(varSelectedRecord.Parcela)
            );
            Value(Parcela);
            Ascending
        )
    )
)

Should the 2000 record limit be an issue, we will have to look at ways to 'prefilter' the data (to get it below 2000 records) and then filter by Parcela on that reduced dataset. You could filter by date (e.g. the date should be later than the selected record) or certain columns should match between the current selected record and the next one. The possible filter condition highly depends on your datamodel, but the aim is to reduce the filtered list to below 2000 records. 

In my example below I will prefilter the dataset by only looking at rows that were created after the current selected plot number:

With(
    {
        //Change LISTNAME
        //Change Date > varSelectedRecord.Date to a valid condition in your datamodel
        filteredList: Filter(LISTNAME, Date > varSelectedRecord.Date)
    };
    Set(
        varSelectedRecord;
        //Give me the first record
        First(
            //Sort by Plot number Ascending (closest value to our current number)
            Sort(
                //Only show me records with a higher plot number
                Filter(
                    //do not change filteredList
                    filteredList;
                    Value(Parcela) > Value(varSelectedRecord.Parcela)
                );
                Value(Parcela);
                Ascending
            )
        )
    )
)

Note: by default the data row limit will be 500, you can change this to up to 2000 within the app settings.

If this solves your question, would you be so kind as to accept it as a solution.

Thanks!

[DdVill]

It worked! Just after adding Value(Parcela). I had to remove the elements of the list which are not numbers because words cannot be se as numbers (which is obvious lol). Also I changed the limit to 2000.

And it is working now! Thank you so so much, you are a star!