Patch checkbox selections in a ForAll loop to Sharepoint

[AnthonyRegnier]

Hello PA community!

I have a tough one to solve here, hoping you can help me out.

1- I have a gallery of item that I can select with a checkbox

2- When I select one, it create a global variable like: set(variable, thisitem)

3- When I uncheck, it puts the variable back to blank

The issue 1:

I can only patch one single item to SharePoint and I would like to be able to select multiple items from the gallery, somehow amend the global variable, put it all in a ForAll loop with the same patching command.

The issue 2:

When I select a second item it overwrites the global variable (obviously) and if I deselect it, it put it back to blank even if the previous item is ticked (obviously).

Here's the code for the patching command:

Patch(
    'Desk Reservations',
    Defaults('Desk Reservations'),
    {
        Title: currentUser.FullName & " " & selectedDesk.Title,
        DeskText: selectedDesk.Title,
        'Check In': startTime,
        'Check Out': endTime,
        'Reserved By': {
            '@odata.type': "#Microsoft.Azure.Connectors.SharePoint.SPListExpandedUser",
            Claims: "i:0#.f|membership|" & currentUser.Email,
            Department: "",
            DisplayName: currentUser.FullName,
            Email: currentUser.Email,
            JobTitle: "",
            Picture: ""
        }
    }
);Navigate(Success)

If you already have a way around this, I'd be happy to hear about it!

Cheers

Anthony

[SkiDK]

Hi @AnthonyRegnier 

I would create a collection with an extra column and assign that one to the gallery.

ClearCollect(colData, AddColumns(SP_List), "Checked", false))

Then assign 'colData' to your gallery as items. Then in the 'Default' option for you checkbox add next:

ThisItem.Checked

 In OnCheck of the checkbox:

Patch(
    colData,
    ThisItem,
    {
        Checked: true
    }
)

In OnUncheck of the checkbox:

Patch(
    colData,
    ThisItem,
    {
        Checked: false
    }
)

So now we will know for each item whether it is checked or not.

To patch the bunch, you can now do next:

ForAll(
  Gallery1.AllItems,
  If(
    Checked,
    Patch(
      'Desk Reservations',
      Defaults('Desk Reservations'), //if you want new, if you want update => link to ThisItem
      {
        Title: ...
      }
    )
  )
)

Hope this helps!

[v-yutliu-msft · Accepted solution]

Hi @AnthonyRegnier ，

Do you want to use multiple selected items in a gallery to update a sharepoint list?

The reason why you met that problem is that one variable could only contain one value or one record.

If you select another item, the previous variable value will not be saved.

I suggest you save selected items to a collection, which could contains multiple items value.

Then use this collection to update.

Please set the checkbox's OnCheck:

Collect(selecteditems,ThisItem)

the checkbox's OnUncheck:

Remove(selecteditems,ThisItem)

 patching command:

ForAll(selecteditems,
Patch(
    'Desk Reservations',
    Defaults('Desk Reservations'),
    {
        Title: currentUser.FullName & " " & selecteditems[@Title],
        DeskText: selecteditems[@Title],
        'Check In': startTime,
        'Check Out': endTime,
        'Reserved By': {
            '@odata.type': "#Microsoft.Azure.Connectors.SharePoint.SPListExpandedUser",
            Claims: "i:0#.f|membership|" & currentUser.Email,
            Department: "",
            DisplayName: currentUser.FullName,
            Email: currentUser.Email,
            JobTitle: "",
            Picture: ""
        }
    }
)
);Navigate(Success)

Best regards,

[AnthonyRegnier]

Thank you guys for your answers!

I'll check that out today or tomorrow latest and let you know!

[v-yutliu-msft · Accepted solution]

Hi @AnthonyRegnier ,

Have you checked my solution?

Have your problem been solved?

If yes, could you mark my answer as solution?
Thanks!

Best regards,

[AnthonyRegnier]

Yes it worked like a charm, thanks a ton!

[kb555]

Hi Team,

I have a similar situation to this post however my challenge is that I need:

Patch Item when check box is checked,

Patch the record to a different SharePoint list (not SharePoint source for Gallery)

If user uncheck the button then record to be removed from SharePoint list

I need a way to keep the checked box checked on the screen if user filter the gallery

thank you, in advance, for your support