Add Row in Gallery - Reset

[CAJ1]

Hi All,

I have created a gallery that I can add rows to. It works perfectly BUT once I submit and go back to the front page and try to create another one I press create to go back to the gallery but there is still a line viable, it has nothing in it but it technically shouldn't be there until the click "Add Row" I have put in the "Reset Gallery" formula but it still doesn't clear it

[EddieE]

@CAJ1 

You need to supply your code for

- The Add Row button

- The Gallery items

- The Delete / Trash can, and

- The Submit button

You can change any data source names, etc that you don't want to share.

[CAJ1]

Add Row Button: 

Collect(
colRowUpdates1,
{
Quantity: "",
CostType: "",
ItemDescription: "",
ReasonforPurchase: txtReason.Text,
FullName: txtFullName.Text,
BusinessUnit: txtBusinessUnit.Text,
JobNumber: cmbJobNumber.Selected.'JOB #',
Supplier: cmbSupplier.Selected.Supplier,
DeliveryAddress: TextInput1.Text,
DeliveryInstructons: txtDeliveryInstructions.Text,
CreatorEmail: Label3.Text,
CostperItem: "",
TotalLineItem: TextInput6.Text,
RowNumber: CountRows(colRowUpdates1) + 1
}
)

Gallery Items:

UpdateIf(colRowUpdates1,RowNumber=ThisItem.RowNumber,{CostperItem:TextInput2,TotalLineItem:Qty*TextInput2})

Trash Can

Remove(colRowUpdates1,ThisItem)

Submit Button:

Patch(
'PR Summaries',
Defaults('PR Summaries'),
{
Name: txtFullName.Text,
'Job Number': cmbJobNumber.Selected.'JOB #',
Supplier: cmbSupplier.Selected.Supplier,
ProcurementType: Dropdown1.Selected.Value,
DeliveryAddress: TextInput1.Text,
DeliveryInstructions: txtDeliveryInstructions.Text,
ReasonforPurchase: txtReason.Text,
DateRequired: DatePicker1.SelectedDate,
Email: Label3.Text,
BusinessUnit: Dropdown2.Selected.Value,
Quote: {
FileName: First(DataCardValue3_1.Attachments).Name,
Value: First(DataCardValue3_1.Attachments).Value
},
TotalValue: Value(TextInput5.Text)
}
);
ForAll(
colRowUpdates1,
Patch(
'Purchase Requisitions',
Defaults('Purchase Requisitions'),
{
Quantity: Quantity,
'Business Unit': BusinessUnit,
Supplier: Supplier,
'Item Description': ItemDescription,
'Job Number': JobNumber,
'Delivery Address': DeliveryAddress,
'Delivery Instructions': DeliveryInstructons,
'Full Name': FullName,
'Cost Type': CostType,
'Reason for Purchase': ReasonforPurchase,
CreatorEmail: CreatorEmail,
'Cost per Item': CostperItem,
'Procurement Type': Dropdown1.Selected.Value,
'Date Required': DatePicker1.SelectedDate,
'Req Summary ID': First(
Sort(
'PR Summaries',
'Summary ID',
SortOrder.Descending
)
).'Summary ID'
}
)
);
ClearCollect(
colRowUpdates1,
Defaults('Purchase Requisitions');
Notify(
"Success",
NotificationType.Success
)
);
Reset(cmbJobNumber);
Reset(cmbSupplier);
Reset(txtDeliveryInstructions);
Reset(txtReason);
Reset(TextInput1);
Reset(Dropdown1);
Reset(DatePicker1);
Reset(DataCardValue3_1);
Reset(Dropdown2);
Reset(Gallery2);
Set(varSuccessPopUp,true)

Does that help?

[developerAJ]

@CAJ1 

Thanks for the code.

The reason you are seeing an item in gallery even before you are clicking an add row is because of code on submit button

ClearCollect(
colRowUpdates1,
Defaults('Purchase Requisitions');
Notify(
"Success",
NotificationType.Success
)
);

this will add a row to colrowupdates1. clear this collection. i am not sure exact reason why you are using this. but if you clear this/remove this there won't be rows added to gallery before clicking Add row button.

If you are using that formula for specific reason let me know it, we can try a different workaround for it.

If i am able to fix your issue, please mark my response as Solution😊

Thank you

Have a good day

[CAJ1]

That is there so that when we have filled in the information and submit the data to a Dataverse table it clears it from that collection.

So, it starts off with the front page and we click the button to “Create New Requisition”, then the page navigates to the purchase req which has been set up like an excel table via a gallery, when you get to the purchase req page there is no line which is how I want it.

Once we enter all the required information and click submit it takes us back to the front page again, but, if we want to put another requisition in straight after the first one and click the “Create New Requisition” button the page transitions again like normal to the purchase req and there is already a line there. This only happens if we immediately go to create another req after the first and so on.

[CAJ1]

We are not supposed to be able to Add a Row until all of the top information has been filled in, you can see the "Add Row" button is disable but that is how we want it we creating any purchase reqs... does that make sense? 

[developerAJ · Accepted solution]

@CAJ1 

"That is there so that when we have filled in the information and submit the data to a Dataverse table it clears it from that collection" . 

if you want to clear the collection use below formula 

Clear(colRowUpdates1);
Notify(
"Success",
NotificationType.Success
);

Above formula will clear the collection.

what is happening when you use formula like this.

ClearCollect(colTest,Defaults(Test)) it add a row to collection with default Values.Please refer the below snip

when you use formula like this 

ClearCollect(colTest,Defaults(Test);Notify("Success",NotificationType.Success))

since you are using the formula similar to above pic. When you click on submit it is adding a row to collection thats the reason you are seeing a row in gallery. just hover on colRowUpdates1 and see the values after clicking submit button you will understand it.

[CAJ1]

Worked perfectly!! Thank you!