Cloning a record using Command Bar Editor

[jimmytheduck]

Hi,

I have a requirement to copy selected columns on a Dataverse record (custom table) into a new record. There are a series of child records which should also be copied across and associated to the record. I'd like to approach this by creating a 'Clone' button using the new command bar editor to avoid installing a smart button solution, however I'm encountering some difficulties passing the 'Parent' cloned record to the Child Records.

I found this blog which offers helpful advice on doing exactly this requirement: Clone records with Power Fx & custom command bar button - Jukka Niiranen, and provides the following code:

Set(ClonedProduct, Patch(Products, Defaults(Products),{Name: "Copy of " & Self.Selected.Item.Name, 'Product Category': Self.Selected.Item.'Product Category', Vendor: Self.Selected.Item.Vendor, Description: Self.Selected.Item.Description})); ForAll(Self.Selected.Item.Assets, Patch(Assets, Defaults(Assets),{Name: "Copy of " & Name, Vendor:ClonedProduct.Vendor, Product:ClonedProduct, 'Purchase Date':Today(), 'Purchased From':'Purchased From', 'Purchase Cost':'Purchase Cost', 'Warranty End Date':'Warranty End Date', Description:Description})); Notify("Product " & Self.Selected.Item.Name & " and its assets have been cloned. Please open the records and update the necessary fields.")

However, the Set() element no longer appears to be supported, and neither is UpdateContext, or Collect or Clear Collect, any ideas on how I could get this to work?

[jimmytheduck · Accepted solution]

If anyone stumbles across this in the future, I managed to resolve the above issue by using the With() function

[J_T]

Copy Record without lines

Notify(
    "Cloning process started. Please wait.",
    NotificationType.Information,
    5000// visible for 5 sec 
);
IfError(
    Navigate(
        Patch(
            Opportunities,
            Defaults(Opportunities),
            {
                Topic: "Copy of " & Self.Selected.Item.Topic,
                Currency: Self.Selected.Item.Currency,
                'Potential Customer': Self.Selected.Item.'Potential Customer'
                // add the fields you want to copy
            }
        )
    ),
    Notify(
        "Error(s): " & Concat(
            AllErrors,
            Message,
            " || "
        ),
        NotificationType.Error
    ),
    Notify(
        "Cloning successfull!",
        NotificationType.Success
    )
)

Copy Record with lines

Notify(
    "Cloning process started. Please wait.",
    NotificationType.Information,
    5000// visible for 5 sec 
);
IfError(
    With(
        {
            // create copy of Opportunity
            _NewOpportunity: Patch(
                Opportunities,
                Defaults(Opportunities),
                {
                    Topic: "Copy of " & Self.Selected.Item.Topic,
                    Currency: Self.Selected.Item.Currency,
                    'Potential Customer': Self.Selected.Item.'Potential Customer'
                    // add the fields you want to copy
                }
            ),
            _OldOpportunityLines: Filter(
                'Opportunity Lines',
                Opportunity.Opportunity = Self.Selected.Item.Opportunity
            )
        },
        With(
            {
                _NewOpportunityLines: ForAll(
                    AddColumns(
                        ShowColumns(
                            // define the columns which you want to copy; use LOGICAL NAME
                            _OldOpportunityLines,
                            "opportunityproductname",
                            "propertyconfigurationstatus",
                            "producttypecode",
                            "quantity"
                        ),
                        // old opportunity lookup needs to be dropped and added with the newly created opportunity
                        "opportunityid",
                        _NewOpportunity
                    ),
                    // update the name column with "copy of " -> not necessary
                    Patch(
                        ThisRecord,
                        {opportunityproductname: "Copy of " & ThisRecord.opportunityproductname}
                    )
                )
            },
            // create copies of Oppotunity lines
            Patch(
                'Opportunity Lines',
                _NewOpportunityLines // patch in bulk
            );
        // navigate to the new opportunity
Navigate(_NewOpportunity)
        )
    ),
    Notify(
        "Error(s): " & Concat(
            AllErrors,
            Message,
            " || "
        ),
        NotificationType.Error
    ),
    Notify(
        "Cloning successfull!",
        NotificationType.Success
    )
);

[NER]

Thanks, it works for me. Life Saver 😊 . By the way, it works for related table data too. Just a small question: how about duplicating success Notify if there is no error and showing success notification? 

Notify("Item Duplicated", NotificationType.Success, 2000);    ??

[J_T]

I updated my previous message. Please have a look.

Also a great blog post regarding this topic:
Command Bar | Power Fx | Clone a record along with child records | Rajeev Pentyala - Microsoft Power...