Copying all records in CollectionA to corresponding record in CollectionB

[sopatte]

I'm copying all the contents of the GroupItems collection onto the same ID in the PSOCache collection. Both collections have the same set of columns. Patch does not work because of the empty fields bug. I'm looking for a succinct way to make this work.

ForAll(
    RenameColumns(GroupItems
        , "ID"
        , "ContentID"
    ),
    UpdateIf(
        PSOCache
        , ID=ContentID
        , {
            Status: Status
            , StatusText: StatusText
            , 'Status Detail': 'Status Detail'
            , Inspected: Inspected
            , MSF: MSF
            , SN: SN
            , Ticket: Ticket
            , 'Vendor Part Number': 'Vendor Part Number'
            , Description: Description
            , Bin: Bin
            , Edited: Edited
        }
    )

[RandyHayes]

@sopatte 

So, you mentioned Patch as an issue, but your formula is using UpdateIf.  Are you having a particular issue with that formula?

[sopatte]

I'm working around the Patch issue.

Yes. I believe there's a scoping issue in my formula. I want to update each record in PSOCache with the contents of the corresponding record in GroupItems.

Also tried:

UpdateIf(
    PSOCache,
    true,
    Lookup(GroupItems,ID=PSOCache[@ID])
)

[RandyHayes]

@sopatte 

At a glance...your initial formula you posted should have worked.  What issues are you finding with it?

[sopatte]

I believe within the record being passed as the third argument to UpdateIf, the values are scoped to PSOCache.

[RandyHayes]

@sopatte 

That may or may not be the case.  I find that PowerApps is usually smart enough to work this out without an issue.  Sometimes..at least 😉 

So, my question would be - have you tried that formula and have you noticed an issue with it that would lead you to a scoping issue?

If so, then perhaps change your individual assignments to statements similar to this:

 {  Status: GroupItems[@Status]
  , StatusText: GroupItems[@StatusText]
  , etc....

[sopatte · Accepted solution]

Your suggestion won't *quite* work because there is no record scope for GroupItems. The record scope within ForAll is 

    RenameColumns(GroupItems
        , "ID"
        , "ContentID"
    )

The documentation says, "If the table being operated upon is an expression, such as Filter( Table, ... ), then the disambiguation operator cannot be used. Only the innermost record scope can access fields from this table expression, by not using the disambiguation operator." although I'm not quite sure what that last sentence means. 

But you did give me an idea. This seems to work:  

ForAll(
    GroupItems,
    UpdateIf(
        PSOCache,
        ID=GroupItems[@ID],
        {
            Status: GroupItems[@Status]
            , StatusText: GroupItems[@StatusText]
            , 'Status Detail': GroupItems[@'Status Detail']
            , Inspected: GroupItems[@Inspected]
            , MSF: GroupItems[@MSF]
            , SN: GroupItems[@SN]
            , Ticket: GroupItems[@Ticket]
            , 'Vendor Part Number': GroupItems[@'Vendor Part Number']
            , Description: GroupItems[@Description]
            , Bin: GroupItems[@Bin]
            , Edited: GroupItems[@Edited]
        }
    )
);
Back()

Thanks!

[sopatte]

I've suggested this feature before but how great would it be if in any record scope ThisItem was defined to refer to the entire record?

ForAll(
    GroupItems,
    UpdateIf(
        PSOCache,
        ID=GroupItems[@ID],
        GroupItems[@ThisItem]
    )
)

[RandyHayes]

@sopatte 

Agreed.

You can get close though with this type of construct:

ForAll(GroupBy(RenameColumns(GroupItems, "ID", "colAID"), "colAID", "ThisItemA"),
UpdateIf(PSOCache, ID=colAID, 
{
            Status: First(ThisItemA).Status
            , StatusText: First(ThisItemA).StatusText
         
etc...