Create an Office365 People Picker to populate a column in a SharePoint Customized Form

[C4men]

I have a SharePoint list and have built a customized form for it in PowerApps.

One of the columns on my list is: Prioritization Partner

1. It is a "person" column type. I would expect someone's name in the column.
2. I can pull that column into my form using an EditForm control - no problems there.

I would like to make it so that the user of the form can:

• Click inside the dropdown and search for any name in our Active Directory (I added the Office365Users connector)
• Click on that name to "add" it to the dropdown (which I named - ComboBox_PrioritizationPartner)
• And then once I submit the form (using patch) that selected name would show up in the SP list

I followed a Reza video and put this in the combo box Items property:

Filter(
Office365Users.SearchUserV2(
{
searchTerm: Trim(Self.SearchText),
isSearchTermRequired: false
}
).value,
AccountEnabled = true && Not("#EXT" in UserPrincipalName)
)

It works in PowerApps as expected, but does not populate the SP list with any value.

I also tried this in the combo box Items property:

Office365Users.SearchUserV2({searchTerm: Self.SearchText}).value

It works in PowerApps as expected, but does not populate the SP list with any value.

Any thoughts here? I'm stumped.

[Amik · Accepted solution]

@C4men -

As I understand it, you have SharePoint list. You have a People field in that list called "Prioritization Partner".

You have created a Customised Form from this list. You modified the Items property of the ComboBox control inside the "Prioritization Partner" DataCard by removing the Choices formula and instead added the Office365 Users table.

In the Update property of the DataCard, use:

{
    DisplayName: 'Your ComboBox Control Name'.Selected.DisplayName,
    Claims: "i:0#.f|membership|" & Lower('Your ComboBox Control Name'.Selected.Mail),
    Department: "",
    Email: Lower('Your ComboBox Control Name'.Selected.Mail),
    JobTitle: "",
    Picture: ""
}

On the DefaultSelectedItems property of the ComboBox, remove "Parent.Default" and instead use:

If(
    !IsBlank(ThisItem.'Prioritization Partner'.Email),
    First(Office365Users.SearchUser({searchTerm: ThisItem.'Prioritization Partner'.Email}))
)

[C4men]

The first formula entered with no errors.

The second formula - for DefaultSelectedItems property - is giving the following error(s):

Incompatible type. The searchTerm column in the data source you're updating expects a 'Text' type and you're using a 'Table' type.

The function 'SearchUser' has some invalid arguments.

Not sure what to do next.

[Amik]

@C4men - please share an image of the error message (hover your cursor over the red line).

[C4men]

Here you go:

[Amik]

@C4men - is your people field multi-choice ?

[C4men]

Yes, it needs to be able to select one or more people

[Amik · Accepted solution]

@C4men - that is a very important detail you forgot to mention.

Similar concept but slight revision:

In the Update property of the DataCard, use:

ForAll(
    'Your ComboBox Control Name'.SelectedItems As _selections,
    {
        DisplayName: _selections.DisplayName,
        Claims: "i:0#.f|membership|" & Lower(_selections.Mail),
        Department: "",
        Email: _selections.Mail,
        JobTitle: "",
        Picture: ""
    }
)

On the DefaultSelectedItems property of the ComboBox, remove "Parent.Default" and instead use:

If(
    !IsBlank(ThisItem.'Prioritization Partner'),
    ForAll(
        ThisItem.'Prioritization Partner' As _selections,
        First(Office365Users.SearchUser({searchTerm: _selections.Email}))
    )
)

[C4men]

That worked! Thank you kindly.

I realized I had two different forms there - one was set to only allow for one person to be selected (your earlier post worked for that) and the other allowed for multiple selections (your solution post worked for that).

Again, thank you!

[migj2003]

Hello

I have the same scenario, but I'm stuck, I tried to follow the step mentioned in the post, but it doesn't work for me and I don't know why, can you please help me out ?

Thanks