Create multiple Attachments in single powerapp screen and share to sharepoint list.

[Anonymous]

How should I create multiple attachments datacards in single powerapp editform screen and send all the attached files to sharepoint list in attachments. I tried to add multiple attachments but they send only one file to sharepoint from first attachment datacard. I need to collect all the files attached in all the attachemnt datacards in sharepoint list. Any way, hack or method would be helpful.

[KayBains]

Microsoft Advice

So, it should be possible, but you would have to do this in a custom way. Your best bet is to use custom cards and add additional upload controls. What you would need to do, when the form is submitted, is patch these extra files as attachments.  You may need to use Power Automate in combination with Power Apps to achieve this.

[KayBains]

See attachment

[Lilian1331]

Thanks @KayBains !

[ashwanidv100]

Unfortunately I don't have access to my this account. I'm started using other account which is @ashwanidv100 

Thanks @KayBains for you responses and answers.

@Lilian1331 ,

Q. How did you resolved this Issue?

A. I was able to consult it through to on my project instead of hitting this wall. I did used multiple attachments using one datacard. As It was yearly data submission at once. I was able to manage to distribute on a monthly basis. So That helped me to save a lot files to not be submit at once but frequently. So In my part was consulting on the possible ways to manage things out, if the system is having limitations.

[ashwanidv100]

@Lilian1331 ,

I was novice at that time, But if you ask me now. 

I would say don't use patch function, but simply use power automate to manage it somehow. 

1. Create a single list and create a 3 Editforms for the same list with different names, Use the attachment datacard. 

2. When submit the forms, Use power Automate and keep the attachments in sharepoint docs or wherevers you like to store them in a specific folder.

3. Use unique name for each folder can be created easily by following a right nomenclature.

4. Generate the link and store it in the SharePoint list column and may call it 'Link to attachments' or 'Something else you like'.

5. And it just instead of storing the files directly to list record it will have a path of where its stored in a SharePoint docs.

Hope this help you somehow to guide you to think about it.

Ash

[KyleJ]

@Lilian1331 
@KayBains @Anonymous 
I have a solution.

When you patch an item, you are able to save the patch to a variable, giving you the newly created ID number. From there, you can patch updates to that same record via ID. 

We know, you can

Patch(YourDatabase,Defaults(YourDatabase),{Field:"Value"},form1.Updates)

But lets expand on this. In ONE SINGLE submission, we need to accomplish a few things. You can first submit the record as above, with 1 of your attachments being submitted. But, lets go ahead and grab the newly created ID by wrapping a Set Variable around the Patch Function. 

Set(PatchedID,Patch(YourDatabase,Defaults(YourDatabase),{Field:"Value"},form1.Updates))

The above code will now submit the record and all fields, and it will add the first attachment, and return to the variable the ID (among other info) 

We can now execute, two additional patch functions. 

Patch(YourDatabase,LookUp(YourDatabase,ID=PatchedID.ID),Form1_1.Updates);
Patch(YourDatabase,LookUp(YourDatabase,ID=PrevPatchedID.ID),Form1_2.Updates);

All together, these three functions (the first being the "Set(Patch())" ) all together will submit multiple attachments from multiple sections of 1 singular form, into 1 single record. 
Finished code should look about like this: 

Set(PrevPatchedID,Patch(Datasource,Defaults(Datasource),{
    Title:TextInput.Text,
},Form1.Updates));

Concurrent(
Patch(Datasource,LookUp(Datasource,ID=PrevPatchedID.ID),Form1_1.Updates),
Patch(Datasource,LookUp(Datasource,ID=PrevPatchedID.ID),Form1_2.Updates)
)

[ashwanidv100]

Thanks @KyleJ , 

Yes, This is one of the possible solutions that someone can think of and may use the same 👏. 

The main intension to my proposed solution was to store the attachments handy and available in structured way (folder wise). Because in generally we ended up using power automate as a part of power suite solution So those files can come handy for sending it forward and do more with that.  

Ash

[Doodooo]

In case anyone else is having trouble handling multiple attachments and stumbled upon this post, as I did, let me explain how I managed to handle it. It's not the most elegant solution, but it works and might help someone in the future.

As has already been mentioned - MS Lists allow to store only 1 attachment in the Attachment column. Therefore, if you need more than 1 attachment per record, your best bet is to create a separate MS List to store just your attachments and link this list via Relationship to your main list.

I created a list that has only 4 columns:

1. Attachment ID - the primary unique column, changed from the default Name and set the Autonumber data type on it
2. Attachment - File data type, stores actual attachments
3. Attachment name - String data type, not really required for this solution to work, but without it you won't be able to see attachment's name in the list.
4. Request ID - reference to the main table's primary column

Then, in order to upload or update the attachments, you need to have a separate form for your attachments in addition to your main form in your Power App that will handle the Attachments. It should consist of only 1 datacard with Attachments control. Make sure that your control has a MaxAttachments property set to more than 1.

This is the formula I used in the OnSuccess property of my main form NewRequestForm. First, it stores the attachments from DataCardValue1 (which is an Attachments control that has Attachments) into a collection, and then we Patch it into the AttachmentsList, which is the aforementioned MS List that stores only attachments. I found that you need to add a column FileName in order for the attachment to be understood by MS Lists, which you can fill in with the values from Name column from the Attachments control.

// Store attachments in a new collection
Set(lastCreateRequest, NewRequestForm.LastSubmit);
ClearCollect(NewAttachmentsCol, AddColumns(DataCardValue1.Attachments, "FileName", Name));

// Upload attachments
ForAll(
    NewAttachmentsCol, 
    Patch(
        'AttachmentsList',
        {
            Attachment: ThisRecord,
            'Attachment Name': ThisRecord.Name,
            'Request ID': lastCreateRequest,
        }
    )
);

There you go, uploading attachments to the list should work now.

Updating attachments in the list is slightly more difficult, as you need to manually keep track of which attachments has been added or removed from the control (at least that's the only solution I found that works). I have a separate form for updating the records called EditRequestForm.

First, you need to load the records into your Attachments control. In my case, I select the record in the RequestIDComboBox which is a ComboBox control linked to my main list.

This is the formula that goes into OnChange property of this Combobox control.

The VariablesCol is a collection that is used to keep track of the current record number in the ForAll loop, as Power Apps don't allow Set formula to be inside the loop. In the formula we just iterate through the attachments and store them in the LoadedAttachmentsCol.

learCollect(VariablesCol, {FirstVar:0});

ClearCollect(LoadedAttachmentsCol,Blank());

ForAll(RequestIDComboBox.Selected.'AttachmentsList',
    Patch(VariablesCol, First(VariablesCol), {FirstVar: First(VariablesCol).FirstVar + 1});

    Collect(
        LoadedAttachmentsCol,
        {
            Name: Last(FirstN(RequestIDComboBox.Selected.'AttachmentsList', First(VariablesCol).FirstVar)).Attachment.FileName,
            Value: Last(FirstN(RequestIDComboBox.Selected.'AttachmentsList', First(VariablesCol).FirstVar)).Attachment.Value,
            ID: Last(FirstN(RequestIDComboBox.Selected.'AttachmentsList', First(VariablesCol).FirstVar)).'Attachment ID'
        }
    );
);

Then, you can set your Attachments control's Items property to reference this newly created LoadedAttachmentsCol. Voila, your attachments are now shown in the control whenever you change the Combobox selection. You might need to change the Name and Value properties too to Name and Value columns accordingly, in case it shows some weird values.

Now, in order to upload these to the list you need to keep track which attachments have been added and which have been removed in the meantime by the user. This is the formula I have on the OnSuccess property of the EditRequestForm that I use for updating my main list. First, it stores currently loaded attachments from the DataCardValue2 (which is also an Attachments Control) in UpdatedAttachmentsCol. Then, it compares it against the initially loaded attachments that we already have stored in LoadedAttachmentsCol and based on the comparisons, it will store this record in either AttachmentsToBeUploadedCol or AttachmentsToBeRemovedCol. Finally, it uploads the new attachments with the Patch formula (same as we did at the beginng when adding new attachments) and removes the not required attachments with the Remove formula by filtering the list by Attachment ID that we grabbed when we loaded the attachments from the list.

// Store updated attachments in collection
ClearCollect(UpdatedAttachmentsCol, AddColumns(DataCardValue2.Attachments, "FileName", Name));

// Compare initially loaded attachments with updated attachments to see which ones are new to upload
ClearCollect(AttachmentsToBeUploadedCol, Blank());
ForAll(
    UpdatedAttachmentsCol,
    If(
        ThisRecord.Value in LoadedAttachmentsCol.Value,
        true,
        Collect(AttachmentsToBeUploadedCol, ThisRecord)
    )
);

// Compare initially loaded attachments with update attachments to see which ones are to be deleted
ClearCollect(AttachmentsToBeRemovedCol, Blank());
ForAll(
    LoadedAttachmentsCol,
    If(
        ThisRecord.Value in UpdatedAttachmentsCol.Value,
        true,
        Collect(AttachmentsToBeRemovedCol, ThisRecord)
    )
);

// Upload new attachments
Set(lastUpdateRequest, EditRequestForm.LastSubmit);
ForAll(
    AttachmentsToBeUploadedCol,
    Patch(
        'AttachmentsList',
        {
            Attachment: ThisRecord,
            'Attachment Name': Name,
            'Request ID': lastUpdateRequest
        }
    )
);

// Remove attachments that need to be removed
ForAll(AttachmentsToBeRemovedCol,
    Remove(
        'AttachmentsList',
        Filter(
            'Sell contract attachments',
            'Attachment ID' = ID
        )
    )
);

// Clear loaded collection to clean the datacard
ClearCollect(LoadedAttachmentsCol, Blank());

That's it. If there is anything unclear - feel free to contact me and I will make sure to explain the best I can.