Filter a gallery by multiselect combobox (multiple filters on the gallery)

[RalfsZ]

Hello,

I've run in to a scenario to which I can't seem to find a solution.
The problem revolves around what is posted in the topic title.

I've gone through Shane's video on Comboboxes, I've gone through Reza's video on Comboboxes but none of the solutions seem to want to work.
I believe it is due to the fact that my gallery is being filtered by other boxes as well as pre-filtered by StartsWith.
The dataset is over 10k entries.

Datasource: Sharepoint List
Includes Project lookup column from another list
App: Entered hours administration app (Hours approval)

Gallery filter code:

Filter(
    'SharepointSource',
    StartsWith(AppStatusPV, "AppPV"),
    IsBlank(Manufh_Edit_ProjectFilter.Selected.Value) || Project.Value = Manufh_Edit_ProjectFilter.Selected.Value,
    IsBlank(ManufH_Edit_PersonFilter.Selected.DisplayName) || Person.DisplayName = ManufH_Edit_PersonFilter.Selected.DisplayName,
    IsBlank(ManufH_Edit_PVDateFilter.SelectedDate) || ManufH_Edit_PVDateFilter.SelectedDate = Day,
    IsBlank(ManufH_Edit_PVHrsFilter.Selected.Value) || Usage.Value = ManufH_Edit_PVHrsFilter.Selected.Value,
    IsBlank(ManufH_Edit_PVLocationFilter.Selected.Value) || Location.Value = ManufH_Edit_PVLocationFilter.Selected.Value
    )

What I want to be able to do:

Filter the gallery by using multiselect on Project and Person filter (or whatever else filter)
As expected, in current iteration the gallery filters by the last selected item if multiselect is enabled for the comboboxes.

What I've tried:
If combobox syntax is changed to SelectedItems, we get a warning that a text (Project column in SP) can't be compared with a table (which SelectedItems produces), which is logical.

Filter(
    'SharepointSource',
    StartsWith(AppStatusPV, "AppPV"),
    IsBlank(Manufh_Edit_ProjectFilter.SelectedItems) || Project.Value in Manufh_Edit_ProjectFilter.SelectedItems,

If I switch to using in "in" place of "=", I get the following error: Invalid Schema, expected a one-column table. Can't add .value after selected items, does not recognize it, which I believe to be because the Project column is not a text column, but a lookup in our SP list from another SP list.

I've also tried what Reza did with a choice column by using:

Last(FirstN(Manufh_Edit_ProjectFilter.SelectedItems,1)).Value,
Last(FirstN(Manufh_Edit_ProjectFilter.SelectedItems,2)).Value,
Last(FirstN(Manufh_Edit_ProjectFilter.SelectedItems,3)).Value,
Last(FirstN(Manufh_Edit_ProjectFilter.SelectedItems,4)).Value,

It produces an empty gallery when the combobox is used - I believe it has to do with that Reza did that with a choice column with limited amount of options, whereas the Project column in our case is a lookup column in Sharepoint to another list which has over 100 entries hence it does not work?

I've also tried creating an Combobox with "on-change" collection within the app when items are selected

ClearCollect(PVEditProjectFilter,Self.SelectedItems)

But when attempting to put that in to action within the Gallery Filter code, I get the same result as previously - Expected a one-column table. There are no variables that I can add after the collection (such as - .Result)

Filter(
    'SharepointSource',
    StartsWith(AppStatusPV, "AppPV"),
    IsBlank(Manufh_Edit_ProjectFilter.SelectedItems) || Project.Value in PVEditProjectFilter.Result,

Any help would be appreciated.

Thank you!

[WarrenBelz]

Hi @RalfsZ ,

You have two many-to-many filters there, so this is not straight-forward. Note the below is free-typed (so watch commas and brackets etc), but this is the pattern you need

With(
   {
      wList:
      Filter(
         'SharepointSource',
         StartsWith(
            AppStatusPV, 
            "AppPV"
         )&&
         (
		   IsBlank(ManufH_Edit_PVDateFilter.SelectedDate) || 
           ManufH_Edit_PVDateFilter.SelectedDate = Day
         ) &&
         (
            IsBlank(ManufH_Edit_PVHrsFilter.Selected.Value) || 
            Usage.Value = ManufH_Edit_PVHrsFilter.Selected.Value
         ) &&
         (
            IsBlank(ManufH_Edit_PVLocationFilter.Selected.Value) || 
            Location.Value = ManufH_Edit_PVLocationFilter.Selected.Value
         )
      )
   },
   With(
      {
         wProject:
         If(
            IsBlank(Manufh_Edit_ProjectFilter.Selected.Value),
            wList,
            Ungroup(
               ForAll(
                  Manufh_Edit_ProjectFilter.SelectedItems As aProject,
                  Filter(
                     wList,
                     aProject.Value in Project.Value
                  )
               ),
               "Value"
            )
         )
      },
      If(
         IsBlank(ManufH_Edit_PersonFilter.Selected.DisplayName),
         wProject,
         Ungroup(
            ForAll(
               ManufH_Edit_PersonFilter.SelectedItems As aPerson,
               Filter(
                  wProject,
                  aPerson.DisplayName in Person.DisplayName
               )
            ),
            "Value"
         )
      )
   )
)  

Please click Accept as solution if my post helped you solve your issue. This will help others find it more readily. It also closes the item. If the content was useful in other ways, please consider giving it Thumbs Up.

MVP (Business Applications)   Visit my blog Practical Power Apps

[RalfsZ]

@WarrenBelz Thank you for the code, brackets and commas seem to be all there. Little translation of variables to local naming and the filtering of multiple selections is now possible.

There is an issue on the visual front, the Gallery appears to be artifacting - rows are there, without data.
Do I need to utilize flexible gallery for this code to work properly (visually)?

**
After additional investigation, the gallery appears to be not working as it should. I can select multiple filters, the items seem to get filtered out to only show those, but entries show up as duplicates one after another, and if the gallery is scrolled through, some entries just disappear (visually, the frame is still there).
If the multiselect filters are not applied, then it works/displays as it should, such as Date, Location...

***
After more playing around, I've seem to have found the issue.
I changed the tag here to AppPVNew2 as well as changed the default value in the source for that column.

With(
   {
      wList:
      Filter(
         'SharepointSource',
         StartsWith(
            AppStatusPV, 
            "AppPVNew2"

I added 5 test entries and it seems to be working fine. 
I don't know how much items there currently are with the previous status AppPVNew (as the app is in development, it is not really used and the status does not change for the Column, a Patch function is used within the app (the approval process) to set it to different name so it does not show up in the gallery.)
Is there any chance that the code will cause the artifacting because of too much entries, similar to a Delegation issue?

Also, would it be possible to pick your brain as to how the With solves this? I read the function documentation, but it refers to, mostly, PowerBI examples 🙂
I see and understand the code itself, just not a clear clue what/why it does what it does.

[WarrenBelz]

Hi @RalfsZ ,

Your issue here (and the reason for the "code gymnastics") is your two many-to-many filters, which require a completely different structure and can only be dealt with in isolation (not incorporated into any other filter). With() simply creates a (very) temporary table (call it a collection if you want to) which you can then chain down with each increment referring to and filtering off the one above. I have a blog on its use in Delegation, but the principle is the same.

Please click Accept as solution if my post helped you solve your issue. This will help others find it more readily. It also closes the item. If the content was useful in other ways, please consider giving it Thumbs Up.

MVP (Business Applications)   Visit my blog Practical Power Apps