Lookup value from Table, but dynamic column

[Anonymous]

Hello,

Consider I have a table like this - TableSy

No	T2	T	Mat A	Mat B	Mat C
1	50.00	50.00	10.00	20.00	30.00
2	100.00	100.00	20.00	40.00	60.00
3	150.00	150.00	30.00	60.00	90.00

I would like to search value in either column Mat A, Mat B, or Mat C. I have a dropdown, named flange1_dd to choose between these 3 columns. I have text input box as well, named no1 to determine which row I want.

I tried this code to find the value:

LookUp(TableSy, Value(no1.Text) = No, flange1_dd.SelectedText.Value)

So when no1 = 1 and flange1_dd = Mat A, it should return 10.00.

However it did not work, it returns the column name instead (Mat A). What should I change in the Lookup command?

Thanks in advance.

[WarrenBelz]

Hi @Anonymous ,

You cannot dynamically refer to Power Apps elements such as column or control names. You need to hard-code it all

With(
   {
      wRecord:
      LookUp(
         TableSy, 
         Value(no1.Text) = No
      )
   },
   Switch(
      flange1_dd.Selected.Value,
      1,
      wRecord.'Mat A',
      2,
      wRecord.'Mat B',
      3,
      wRecord.'Mat C'
   )
)

Please click Accept as solution if my post helped you solve your issue. This will help others find it more readily. It also closes the item. If the content was useful in other ways, please consider giving it Thumbs Up.

Visit my blog Practical Power Apps

[Anonymous]

I see, however this is only a dummy table. An actual table has 100+ columns of Mat A, Mat B, Mat C and so on! Is there a workaround to this?

My intention was actually to get an interpolation of data. The original table is actually like this (TableSyt):

Mat	50.00	100.00	150.00
Mat A	10.00	20.00	30.00
Mat B	20.00	40.00	60.00
Mat C	30.00	60.00	90.00

but I transposed it to use Lookup function.

I have a dropdown, named flange1_dd to choose between these 3 columns.

I have text input box as well, named Temp and I can input any number I want, between 50 to 150.

I.e. if I choose Mat A, and input 75 (this value is between 50 and 100), I have another text box, named Sy that will interpolate values between 10 and 20 (since 10 falls under 50 column, and 20 falls under 100 column, in row Mat A)

[WarrenBelz]

Hi @Anonymous ,

Sorry this is not Excel with a vlookup . . . you have a lot of hard-coding ahead if you have that many columns - maybe you need to re-consider the data structure.

Please click Accept as solution if my post helped you solve your issue. This will help others find it more readily. It also closes the item. If the content was useful in other ways, please consider giving it Thumbs Up.

Visit my blog Practical Power Apps

[Anonymous]

Is there a solution or guide that you can share on how can I do this?

[WarrenBelz]

Hi @Anonymous ,

I would have a field called Mat set to A, B C etc with a record for every item combination. Messy, but your model seems to require it.

Please click Accept as solution if my post helped you solve your issue. This will help others find it more readily. It also closes the item. If the content was useful in other ways, please consider giving it Thumbs Up.

Visit my blog Practical Power Apps

[WarrenBelz]

Hi @Anonymous ,

Just checking if you got the result you were looking for on this thread. Happy to help further if not.

Please click Accept as solution if my post helped you solve your issue. This will help others find it more readily. It also closes the item. If the content was useful in other ways, please consider giving it Thumbs Up.

Visit my blog Practical Power Apps

[eccountable]

There is a solution to finding a value based on a dynamically defined column!!!

I used the Column() function to extract the value I needed from the Lookup(), however it is a bit more involved because Column() function requires an "Untyped Object" data type as the first parameter, and the only function that returns that kind of data is ParseJSON(). Fortunately, the JSON() function will serialize a record returned by Lookup().

First, use Lookup(<table>,<formula>) to return a record without a column - Do Not specify the column in the 'reduction formula' as it suggests in the documentation. Once you have that working, wrap that expression with Column(ParseJSON(JSON(...)), <expression that contains the column name>)

In my case, my data contains a polymorphic column (ex: Dataverse Owner field), so I had to wrap the control's Items collection with DropColumns() (see below).  

My use-case was that I was using a Fluent DetailsList (DetailsList control reference - Power Platform | Microsoft Learn) that contains "Link" type columns. If you are not familiar with this AWESOME control as an alternative to a Gallery, watch this video  https://www.youtube.com/watch?v=9xDXLvGiRPM from @ScottDurow (Thanks SD!)

This is a fictitious list of banks and interest rates (obviously) and the goal is that when the user clicks on the interest rate in then add it to a "shopping cart":  

When the user clicks on the rate, the DetailList control's OnChange was able to get the name of the column in a property called "Self.EventColumn", and the Row ID is passed in through a property called "Self.EventRowKey".

The OnChange in my DetailList control looks like this:

If(
    Self.EventName = "CellAction",                      // we only need to capture the user clicking on a "link" cell 
    ClearCollect(
        gColShoppingcart,
        {
            ecc_rateid: GUID(Self.EventRowKey),
            ecc_column: Self.EventColumn,
            ecc_rate: Column(
                ParseJSON(
                    JSON(
                        LookUp(
                            DropColumns(                    
                                gColRates,                  // collection of rates used in Items for the DetailsList
                                "_ownerid_value"            // this field references more than one table (aka Polymorphic) which JSON cannot deal with
                            ),
                            Rate = GUID(Self.EventRowKey)   // the lookup finds the one row I need using the PK to the table
                        )
                    )
                ),
                Self.EventColumn                            // this is the 2nd parameter passed to the Column() function and contains the name of the column as a string
            )
        }
    )
);

when the user clicks on the rate, it is added to the collection

 I put the name of the column into the collection for demonstration.