Merge 2 Dataverse tables into one collection

[memphis11]

Hello, everyone,

I have a question about merging two tables from Dataverse.

I create two collections based on certain values:

ClearCollect(mySCH;
ShowColumns(tbl_SCHSCHImport;
"kol__guid";
"kol__Surname";
"kol__class";
"kol__password"

));;

ClearCollect(myTEACHER;
ShowColumns(tbl_SCHTeacher;
"kol__subject";
"kol__teacher";
"kol__class"
));;

now i would like to merge both collections into one, and this based on the column kol__class

My attempt:

ClearCollect(myTable;
Ungroup(
DropColumns(
AddColumns(
myTEACHER;
"myGroupedColumn";
Filter(
mySCH;
kol__class=myTEACHER[@kol__class]
)
);
"kol__class"
);
"myGroupedColumn"
)
);;

Unfortunately I have the problem that my
values are not displayed in the new collection (myTable) with this formula

greetings

[poweractivate]

@memphis11 

Supposing collections abcd and efc,

and wanting abcdef joining on column "c" (with "c" being like kol__class in your case)

Use this formula:

ClearCollect(abcd,{a:1,b:2,c:3,d:4},{a:11,b:22,c:33,d:44});
ClearCollect(efc, {e:5,f:6,c:3}    ,{e:55,f:66,c:33});
ClearCollect
(
     abcdef
    ,ForAll
     (
         abcd As SCH
         ,With
         (
            {TCH:LookUp(efc,c=SCH.c)}
           ,{a:SCH.a,b:SCH.b,c:SCH.c,d:SCH.d,e:TCH.e,f:TCH.f}
         
         )
     )

);

The collection abcdef will look like this now:

Working Sample msapp

I have attached a working sample msapp file app_merge_abcdef.msapp if you would like to import a full, working example yourself for your convenience.

To use the sample msapp attached, follow these steps:

1) Download the msapp file attached to this post (it's at the bottom of this post), to Desktop or a folder of your choice, by clicking on it from this post.

2) Create a new, blank Power App Canvas App

3) Go to File -> Open -> Browse

4 ) Navigate to location of .msapp file from Step 1, select it, and press the "Open" button.

5 ) The working example msapp file should load

6 ) Toggle between Screen2 and Screen1 once to initialize all the collections, if needed.
7 ) You can check File -> Collections to see the Collections preview

In this sample app, the formula is in the OnVisible property of Screen1

See if it helps @memphis11 

[poweractivate]

@memphis11 

In your specific case, it would be something like this.

//pseudocode, not tested. 
//Beware of the list separator delimiters ; rather than , used here
//Beware of the chaining operator ;; rather than ; used here


ClearCollect(mySCH;
ShowColumns(tbl_SCHSCHImport;
"kol__guid";
"kol__Surname";
"kol__class";
"kol__password"

));;

ClearCollect(myTEACHER;
ShowColumns(tbl_SCHTeacher;
"kol__subject";
"kol__teacher";
"kol__class"
));;

//I am assuming the above code you originally gave works properly. 
//If not, you may need to adjust it.
//You can also try mock data instead of the above lines you gave, like
//ClearCollect(mySCH;{kol__guid:"SCH.kol__guid";kol__Surname:"SCH.kol__Surname";kol__class:"SCH.kol__class";kol__password:"SCH.kol__password"});;
//ClearCollect(myTEACHER;{kol__subject:"TCH.kol__subject";kol__teacher:"TCH.kol__teacher";kol__class:"TCH.kol__class"});;

ClearCollect
(
     myTable
    ;ForAll
     (
         mySCH As SCH
         ;With
         (
            {TCH:LookUp(myTEACHER,kol__class=SCH.kol__class)}
           ;{kol__guid:SCH.kol__guid;kol__Surname:SCH.kol__Surname;kol__class:SCH.kol__class;kol__password:SCH.kol__password;kol__subject:TCH.kol__subject;kol__teacher:TCH.kol__teacher}
         
         )
     )

);;
//if the above does not work, try removing the code you originally gave, and uncomment the two mock lines. If you see it appearing to work then, there might be an issue with the ClearCollect lines you originally gave, which you might need to adjust if that is the case.

You may need to adjust the code above if it contains errors, I cannot test your scenario specifically since it is using your Dataverse data set up in a specific way. If you prefer, you may want to start with my working, tested initial post, and adjust it from there.

In case the above really works even untested, then I provide the specific example above for your particular scenario, just in case it helps you further @memphis11 . If the above does work, it should give you the collection you want in myTable. 

[memphis11]

Hello,

unfortunately I still have a problem.

I'll send the code in German:

//Create two collections
ClearCollect(mySCH;
ShowColumns(tbl_SCHSchuelerImport;
"kol__guid";
"kol__nachname";
"kol__vorname";
"kol__klasse";
"kol__anmeldename";
"kol__passwort"

));;

ClearCollect(myTEACHER;
ShowColumns(tbl_SCHZuordnungLehrer;
"kol__fach";
"kol__lehrer";
"kol__klasse"
));;

//Zusammenführung der beiden Tabellen und deren Zuweisung zur Klasse
ClearCollect
(
myTable;
ForAll
(
mySCH As SCH
;With
(
{TCH:LookUp(myTEACHER;kol__klasse=SCH.kol__klasse)}
;

{kol__guid:SCH.kol__guid;kol__nachname:SCH.kol__vorname;kol__klasse:SCH.kol__klasse;kol__passwort:SCH.kol__passwort;kol__fach:TCH.kol__fach;kol__lehrer:TCH.kol__lehrer}

)
)

);;

The result in the collection looks like this:

Unfortunately, the assignment does not match

[memphis11]

Collection1: (mySCH);

Collection2: (myTeacher);

[poweractivate]

@memphis11 

The only issue I see might be a minor one, that 

kol__nachname:SCH.kol__vorname

should say

kol__nachname:SCH.kol__nachname

Is this the only issue? You are indicating you might have another problem.

I do have a question:

You want to do a Join on kol__klasse.

However, you can have more than one student with the same kol__klasse?

For a Join, the foreign key must be unique.

If it's not unique, it looks like you are trying to do something else.

Since more than one student can be in the same class, (which would make sense), 

it looks like you are trying to do something other than a regular Join.

Could you specify what you are attempting to do exactly?

In the meantime, I'll see if I can presume what you might be doing. It looks more like you're trying to do some sort of data flattening, where you want any rows from your other table TCH that have the same Class on the outer table SCH, to then repeat the same row in SCH based on the augmented table, and use that augmented data on those rows. Just in case that is correct, I'll use that as the assumption and might provide a response shortly.

[poweractivate]

@memphis11 

Try this instead:

Use this for the OnVisible of Screen1:

ClearCollect(abcd,{a:1,b:2,c:3,d:4},{a:11,b:22,c:33,d:44});
ClearCollect(
             efc, {e:50,f:60,c:3}    ,{e:550,f:660,c:33}
                , {e:51,f:61,c:3}    ,{e:551,f:661,c:33}
            );
ClearCollect
(
     abcdef
    ,ForAll
     (
         efc As TCH
         ,With
         (
            {SCH:LookUp(abcd,c=TCH.c)}
           ,{a:SCH.a,b:SCH.b,c:SCH.c,d:SCH.d,e:TCH.e,f:TCH.f}
         
         )
     )

);

Working Sample msapp

I have attached a working sample msapp file app2_merge_abcdef.msapp if you would like to import a full, working example yourself for your convenience.

To use the sample msapp attached, follow these steps:

1) Download the msapp file attached to this post (it's at the bottom of this post), to Desktop or a folder of your choice, by clicking on it from this post.

2) Create a new, blank Power App Canvas App

3) Go to File -> Open -> Browse

4 ) Navigate to location of .msapp file from Step 1, select it, and press the "Open" button.

5 ) The working example msapp file should load

6 ) Toggle between Screen2 and Screen1 once to initialize all the collections, if needed.
7 ) You can check File -> Collections to see the Collections preview


-----------------
Explanation:

In order to repeat the rows from the augmented table, simply switch the ForAll and With parts from my original example, starting with the augmented table efc (TCH) in the ForAll and the outer table (SCH) for the With  (instead of the outer table abcd (SCH) as the ForAll)

So instead of

//this version only works well if there is one TCH.c per SCH.c
ForAll
(
    abcd As SCH
    ,With
    (
       {TCH:LookUp(efc,c=SCH.c)}
      ,........
         
    )
)

Use:

//this version will repeat the corresponding row of SCH.c again based on each row of TCH
ForAll
(
    efc As TCH
    ,With
    (
       {SCH:LookUp(abcd,c=TCH.c)}
       ,............
         
    )
)

So then you get this:

[poweractivate]

@memphis11 

Alright, now if you have repeated rows in kol__klasse in BOTH collections

Then you may want this:

In the above example, SortByColumns(source,"c",Ascending) is used on each data table, to make it clearer.

If you want something like the above, use this formula:

ClearCollect(abcd,{a:10,b:20,c:3,d:40},{a:110,b:220,c:33,d:440}
                 ,{a:10,b:21,c:3,d:41},{a:111,b:221,c:33,d:441}
            );
ClearCollect(
             efc, {e:50,f:60,c:3}    ,{e:550,f:660,c:33}
                , {e:51,f:61,c:3}    ,{e:551,f:661,c:33}
            );

Clear(abcdef);

ForAll
(
    efc As TCH
    ,ForAll
    (
        abcd As SCH  
        ,If(SCH.c = TCH.c,Collect(abcdef,{a:SCH.a,b:SCH.b,c:SCH.c,d:SCH.d,e:TCH.e,f:TCH.f}))
    
    
    )
);

Working Sample msapp

I have attached a working sample msapp file app3_merge_abcdef.msapp if you would like to import a full, working example yourself for your convenience.

To use the sample msapp attached, follow these steps:

1) Download the msapp file attached to this post (it's at the bottom of this post), to Desktop or a folder of your choice, by clicking on it from this post.

2) Create a new, blank Power App Canvas App

3) Go to File -> Open -> Browse

4 ) Navigate to location of .msapp file from Step 1, select it, and press the "Open" button.

5 ) The working example msapp file should load

6 ) Toggle between Screen2 and Screen1 once to initialize all the collections, if needed.
7 ) You can check File -> Collections to see the Collections preview

[poweractivate · Accepted solution]

@memphis11 

For you, try something like:

//pseudocode - not tested

//Create two collections
ClearCollect(mySCH;
ShowColumns(tbl_SCHSchuelerImport;
"kol__guid";
"kol__nachname";
"kol__vorname";
"kol__klasse";
"kol__anmeldename";
"kol__passwort"

));;

 

ClearCollect(myTEACHER;
ShowColumns(tbl_SCHZuordnungLehrer;
"kol__fach";
"kol__lehrer";
"kol__klasse"
));;

 
Clear(myTable);;

ForAll
(
    mySCH As TCH
    ;ForAll
    (
        myTEACHER As SCH  
        ;If(SCH.kol__klasse = TCH.kol__klasse;Collect(myTable;{kol__guid:SCH.kol__guid;kol__nachname:SCH.kol__nachname;kol__klasse:SCH.kol__klasse;kol__passwort:SCH.kol__passwort;kol__fach:TCH.kol__fach;kol__lehrer:TCH.kol__lehrer}))
    
    
    )
);

See if it helps @memphis11 

[memphis11]

Good morning, perfect, that works. Many Thanks