Mismatch between Lookup Function and Gallery Item

[BLuca]

Hello everyone,
I'm building an app where I scan for a QR code and then update some values on a Sharepoint List.

Most of the items I'm scanning have a Serial Code, so they are unique values.
Some items don't have a serial number (their serial value is set to "no serial"), so I decided to create an "item pool" (there will be many items of the same kind), by creating a new coulmn on the list, named "Quantity", which must increase or decrease by 1 depending on which kind of scan I do (take or return).
I also created a Gallery in which every item is listed so I could eventually compare with it.

Here's the issue: once the item has been found, I can pretty much update every column right (so that I know that I found the right item), the Quantity value is updated with the next item on the list, instead of the same row value.
For example: The item I'm scanning has quantity 4 and the next item on the list has quantity 2. If I scan for the Item to be taken, I'm getting the updated value of Quantity to 1 (next item quantity-1) instead of getting 3(my item quantity-1) (and it does the same with the return operation).
All of this operations are inside the same Patch function so it doesn't make sense to me why the other values are updated correctly but not this one.

Is this some kind of bug or am I missing something?

I hope my explanation of the issue is understandable.
Please help, thank you!!

P.S.: I could also upload screenshots of the code, I will do it soon.

[BCBuizer]

Hi @BLuca ,

Can you please share the Patch formula? Not only as a screenshot, but also as text since that saves a lot of typing and decreases the probability of mistakes when suggesting a solution.

[BLuca]

Hi @BCBuizer,
here's the code for the patch function:

ForAll( //No serial Branch

Gallery2.AllItems; //Gallery2 has only "no serial" items
Patch(

DemoItemLaboratorio;
LookUp(DemoItemLaboratorio;

(('Serial number' = Seriale) //Seriale variable is set OnScan (in this case will find "no serial")

&& (Title = Oggetto) //Also set OnScan
&& (Office.Value = Ufficio)) //Also set OnScan

);

{

Customer: CustomerName.Text; //Ok

'Previous Owner': If(IsBlank(Text(CurrentOwnerList2));Text('Previous Owner');Text(CurrentOwnerList2)); //Ok
'Current Owner': Text(User); //Ok
Quantity: QuantityList2-1; //Quantity values from Sharepoint List listed in Gallery2

//Also tried with Quantity: Quantity-1

//Print of Quantity alone, gives the quantity value of the next record

'Serial?': false; //Ok
'Request date': (Today()); //Ok

Status: If(Quantity = 0;{Value: "In use"};{Value: "Available"}); //not even tested this one, it will come later

'Due date': (Today() + 15) //Ok

}
));

[BCBuizer]

Hi @BLuca ,

The issue is that you are not referencing the current record in the ForAll loop, but the control in the gallery. Because of this, it will always pick the value of the last item in the gallery. To fix this, include a reference to ThisRecord:

ForAll( //No serial Branch

Gallery2.AllItems; //Gallery2 has only "no serial" items
Patch(

DemoItemLaboratorio;
LookUp(DemoItemLaboratorio;

(('Serial number' = Seriale) //Seriale variable is set OnScan (in this case will find "no serial")

&& (Title = Oggetto) //Also set OnScan
&& (Office.Value = Ufficio)) //Also set OnScan

);

{

Customer: CustomerName.Text; //Ok

'Previous Owner': If(IsBlank(Text(CurrentOwnerList2));Text('Previous Owner');Text(CurrentOwnerList2)); //Ok
'Current Owner': Text(User); //Ok
Quantity: ThisRecord.QuantityList2-1; //Quantity values from Sharepoint List listed in Gallery2

//Also tried with Quantity: Quantity-1

//Print of Quantity alone, gives the quantity value of the next record

'Serial?': false; //Ok
'Request date': (Today()); //Ok

Status: If(Quantity = 0;{Value: "In use"};{Value: "Available"}); //not even tested this one, it will come later

'Due date': (Today() + 15) //Ok

}
));

[BLuca]

Hi @BCBuizer ,
thank you for the tip.
It is not working, unfortunately.
My list has 4 items now and their quantities are 1, 8, 4, 7. I'm trying to take item that has 8 as quantity and the operation returns 6 instead of 7. Same when I try to increase the value, it goes from 6 back to 8. Every other value of the same record is updated correctly.
Also, I had to use ThisRecord.QuantityList2.Text -1 because otherwise it gives an error message with data type.
I even tried to let go of the Gallery and just type ThisRecord.Quantity+1 but the result is the same as before.

[BCBuizer]

Hi @BLuca ,

In that case something may be happening outside of what you see. When I tested this my self it was working as expected. Please try using Monitor to perform a debug. More information on how to use Monitor can be found here: https://learn.microsoft.com/en-us/power-apps/maker/monitor-canvasapps

[BLuca]

Hi @BCBuizer,
I tried as your suggestion, but I can't really see anything about that error message.
The only errors I could see are about connections with the Sharepoint List (I don't know why the error shows up given that I already have all the connections right), but my patch formulas are marked as successfuly executed.
Shall I upload the TraceEvents file here so you can see?
Maybe is there something wrong with my Sharepoint List instead of the App? Quantity field is the only one as Number type, maybe I can try with simple Text.

Any other thoughts?
Thank you!

[BCBuizer]

Hi @BLuca ,

Please feel free to share the trace file as long as it does not contain any data that shouldn't be publicly available.

[BLuca]

Hello @BCBuizer 
Here's the zip file with the json inside (removed).
Please check and let me know if you see anything strange.

Thank you.

[BCBuizer]

Hi @BLuca ,

Perhaps I understood the initial requirement wrong. So when you scan, you want the quantity of the scanned item to decrease by 1, right? If yes, then the issue is that you are using a ForAll loop. Because this loops through all items in the gallery, and then patches the selected item (ID = 60 in the case of what is in the trace you sent) 4 times with all Quantity values of the items in Gallery2. Since each Patch overwrites the previous, the value for the last item is the one that sticks.

In case I now understood what you want to achieve correctly, removing the ForAll look will fix the issue:

Patch(
	DemoItemLaboratorio;
	LookUp(
		DemoItemLaboratorio;
		(('Serial number' = Seriale) //Seriale variable is set OnScan (in this case will find "no serial")
		&& (Title = Oggetto) //Also set OnScan
		&& (Office.Value = Ufficio)) //Also set OnScan
	);
	{
		Customer: CustomerName.Text; //Ok
		'Previous Owner': If(IsBlank(Text(CurrentOwnerList2));Text('Previous Owner');Text(CurrentOwnerList2)); //Ok
		'Current Owner': Text(User); //Ok
		Quantity: Quantity-1; //Changed this due to removal of the ForAll loop
		'Serial?': false; //Ok
		'Request date': (Today()); //Ok
		Status: If(Quantity = 0;{Value: "In use"};{Value: "Available"}); //not even tested this one, it will come later
		'Due date': (Today() + 15) //Ok
	}
);