Patch not inserting record in sharepoint list

[erikasampang]

Hi Community,

I am very new to powerapps. I've been stuck on this basic inserting for the past 2 days now and i really need help. I wish to use Patch to insert my records. I am not using a form, it is various input fields which I will then retrieve the input and store. I look through a lot of posts and answers before this, making sure that the internal columns are the same, making sure to input the Title etc. There is no error shown, after submitting, it "works", but when i check the sharepoint list, it's empty no record(s) at all that was created. The process is wizard pages, ending with a summary page, and at the summary page there is a submit button. I am using text labels in the summary pages, i use those text displayed in those labels to insert in the list. Any help is greatly appreciated!!

This is what I put in the submit button. Even when i put e.g DisplayApplicationNumber.Text , no records is inserting

Set(
    varTotalApplicationCounter,
    CountRows(ApplicationList) + 1
);

Patch(
     ApplicationList,
     Defaults(ApplicationList),
     {
          Title: "ApplicationList",
          ApplicationNumber: DisplayApplicationNumber,
          TotalRLength: DisplayTotalRequestedLength,
          CompanyLeasing: DisplayCompanyLeasing,
          CBDType: DisplayCBDType,
          Status: "Pending",
          TotalLocations: CountRows(LocationCollection),
          Remarks: DisplayRemarks,
          ExtractionProration: false
     }
);

I am also trying to insert a collection into the sharepoint list and similar to the above, it's not inserting even though there are no errors.

ForAll(
     LocationCollection,
     Patch (
         LocationList,
         Defaults(LocationList),
         {
               Title: "LocationList",
               StartingPoint: DisplaySummaryStartingPoint,
               EndingPoint: DisplayEndingPoint,
               Total_SPipes: DisplaySummarySparePipes,
               CBDType: DisplaySummaryCBDType,
               Pipe_RLength: DisplaySummaryLength,
               Status: "Pending"
         }
     )
);

This is the two sharepoint lists , left is ApplicationList and right is LocationList. I left almost all of it not required as I was still testing out how to insert.

This is how the summary page looks like

Thank you!!!

[WarrenBelz · Accepted solution]

Hi @erikasampang ,

The item you have not stated is what are the references starting with Display ?Assuming they are Text controls or labels

With(
   {
      wRows:
      Text(CountRows(ApplicationList) + 1)
   },
   Patch(
      ApplicationList,
      Defaults(ApplicationList),
      {
          Title: "ApplicationList",
          ApplicationNumber: wRows,
          TotalRLength: Value(DisplayTotalRequestedLength.Text),
          CompanyLeasing: DisplayCompanyLeasing.Text,
          CBDType: DisplayCBDType.Text,
          Status: "Pending",
          TotalLocations: CountRows(LocationCollection),
          Remarks: DisplayRemarks.Text,
          ExtractionProration: false
      }
   )
);

For the collection, have you ensured there is data in it and the field names match what you have ?

Please click Accept as solution if my post helped you solve your issue. This will help others find it more readily. It also closes the item. If the content was useful in other ways, please consider giving it Thumbs Up.

Visit my blog Practical Power Apps

[erikasampang]

There are some columns i did not insert a value as i intend to leave them blank. all are text labels. Yes there are data in the collection. In the summary page, you can see that there are data from the collection that are being displayed. May I understand for the code you posted, why did you use 'With' ? is it more efficient compared to going straight into Patch? Thank you!

[WarrenBelz · Accepted solution]

Hi @erikasampang ,

You do not really need the With() in this case, I just find it makes the Patch easier to read and follow. The real issue here is getting compatible values on each side of all the items and I was guessing a bit on some of them as I do not know what the source values are. You have posted the field types, and if they are Labels, then .Text needs to be after them (although is this the field name or the label name?). I also assume they are on the screen and not in a Gallery.

In your ForAll post, I need to assume they are field names. Again - I am "flying blind" a bit as I really need to know exactly what these values refer to.

Patch (
   LocationList,
   ForAll(
      LocationCollection,
      {
         Title: "LocationList",
         StartingPoint: DisplaySummaryStartingPoint,
         EndingPoint: DisplayEndingPoint,
         Total_SPipes: Value(DisplaySummarySparePipes),
         CBDType: DisplaySummaryCBDType,
         Pipe_RLength: Value(DisplaySummaryLength),
         Status: "Pending"
      }     
   )
)

Please click Accept as solution if my post helped you solve your issue. This will help others find it more readily. It also closes the item. If the content was useful in other ways, please consider giving it Thumbs Up.

Visit my blog Practical Power Apps

[erikasampang]

Hi @WarrenBelz ,

ahh i understand. yes they are the label names. For ApplicationList, the label names i used are on the screen, while for LocationList, the label names are in the gallery.

This is the Labels that i use for the ApplicationList, i'll use what is displayed in that text to store.

For the gallery, here is the text labels

[WarrenBelz]

@erikasampang ,

But you are patching the collection, not the gallery, so those fields are not in it. After reading what I have posted, can you please attempt some code so I have some idea what to start helping you with - you can start with Gallery.AllItems in your ForAll if you want to patch those calculated labels.

[erikasampang · Accepted solution]

hi @WarrenBelz ,

For the ApplicationList and CollectionList, it finally insert when i added the Value() and the .Text. thank you so much!! It's definitely my fault I did not think to add .Text and Value().

Patch(
      ApplicationList,
      {
          Title: "ApplicationList",
          ApplicationNumber: DisplayApplicationNumber.Text,
          Total_RLength: Value(DisplayTotalRequestedLength.Text),
          CompanyLeasing: DisplayCompanyLeasing.Text,
          CableType: DisplayCableType.Text,
          CBDType: DisplayCBDType.Text,
          Status: "Pending",
          TotalLocations: CountRows(LocationCollection),
          Remarks: DisplayRemarks.Text,
          ExtractProration: false
      }
)

Patch (
 LocationList,
 ForAll(
   LocationCollection,
    {
      Title: "LocationList",
      StartingPoint: DisplaySummaryStartingPoint.Text,
      EndingPoint: DisplaySummaryEndingPoint.Text,
      Total_SPipes: Value(DisplaySummarySparePipes.Text),
      Total_APipes: Value(DisplaySummaryAppliedPipes.Text),
      CBDType: DisplaySummaryCBDType.Text,
      Pipe_RLength: Value(DisplaySummaryLength.Text),
      Status: "Pending"
    }
 )
)