Retain some form data after submitting

[ashleylinkewich]

Hi everyone, 

I have a form here that has a couple lookup controls (operator, machine), option set (shift) and data card (heat no) that I would like to retain after I submit the form so the operator doesn't have to input and lookup the values each time. 

I tried following the solution found at: 

https://powerusers.microsoft.com/t5/Building-Power-Apps/Retain-some-form-data-after-submitting/m-p/4...

with only the heat number being retained. I believe this is because its a data card versus lookup/option set. 

Can anyone suggest how I would do the same for the lookup/option sets? 

Thank you!

[WarrenBelz]

Hi @ashleylinkewich ,

When you say "retain" are you asking that these values are used as defaults in a subsequent new record?

This is best done by setting the value as a Variable on the SubmitForm code and then setting the Default of the item to this variable.

Can you please send your code for submitting the form.

[ashleylinkewich]

Yes, exactly - set as defaults. 

Like I said, I was able to do this with the value cards, but not dropdowns (option sets & lookups) 

My code for submit is as follows: 

If(
    And(
        (DateValue6.SelectedDate) = (DateValue5.SelectedDate),
        Value(HourValue5.Selected.Value) > Value(HourValue6.Selected.Value)
    ),
    SubmitForm(Form2);
            Set(
                currentOPERATOR,
                Form2.LastSubmit.Operator2
            );
            Set(
                currentMACHINE,
                Form2.LastSubmit.MachineLookup
            );Set(
                currentSHIFT,
                Form2.LastSubmit.Shift
            );Set(
                currentHEATNO,
                Form2.LastSubmit.HeatNumber
            );
            NewForm(Form2);,
    If(
        And(
            DateValue6.SelectedDate = DateValue5.SelectedDate,
            Value(HourValue5.Selected.Value) < Value(HourValue6.Selected.Value)
        ),
        Notify(
            "Finish time can't be before start time",
            NotificationType.Error
        ),
        If(
            And(
                DateValue5.SelectedDate > DateValue6.SelectedDate,
                Value(HourValue5.Selected.Value) < Value(HourValue6.Selected.Value)
            ),
            SubmitForm(Form2);
            Set(
                currentOPERATOR,
                Form2.LastSubmit.Operator2
            );
            Set(
                currentMACHINE,
                Form2.LastSubmit.MachineLookup
            );Set(
                currentSHIFT,
                Form2.LastSubmit.Shift
            );Set(
                currentHEATNO,
                Form2.LastSubmit.HeatNumber
            );
            NewForm(Form2);
            ,
            If(
                And(
                    DateValue5.SelectedDate > DateValue6.SelectedDate,
                    Value(HourValue5.Selected.Value) > Value(HourValue6.Selected.Value)
                ),
                Notify(
                    "Shift can't be more than 24 hours",
                    NotificationType.Error
                ),
                If(
                    DateValue5.SelectedDate < DateValue6.SelectedDate,
                    Notify(
                        "Finish date can't be before start date",
                        NotificationType.Error
                    ),
                    If(
                        IsMatch(
                            (DataCardValue21.Text),
                            "\.",
                            MatchOptions.Contains
                        ),
                        SubmitForm(Form2);
            Set(
                currentOPERATOR,
                Form2.LastSubmit.Operator2
            );
            Set(
                currentMACHINE,
                Form2.LastSubmit.MachineLookup
            );Set(
                currentSHIFT,
                Form2.LastSubmit.Shift
            );Set(
                currentHEATNO,
                Form2.LastSubmit.HeatNumber
            );
            NewForm(Form2);,
                        Notify(
                            "Weight must be in tonnes",
                            NotificationType.Error
                        )
                    )
                )
            )
        )
    )
)

(sorry its so long - I have a bunch of errors built in if the time isn't entered in 24hr)

And then the default for each is set to their respective variable as such: 

currentOPERATOR

Thank you for your help! 

[WarrenBelz]

Hi @ashleylinkewich ,

I have found the LastSubmit function to be a little unreliable at times, however you do not need to use it.

Just set the variables to the form control values before SubmitForm so

If(
   DateValue6.SelectedDate) = (DateValue5.SelectedDate) &&
   Value(HourValue5.Selected.Value) > Value(HourValue6.Selected.Value
   ,
   Set(
      currentOPERATOR,
      YourCurrentOperatorControlValue
   );
   Set(
       currentMACHINE,
       YourCurrentMachineControlValue
   );
   Set(
       currentSHIFT,
       YourCurrentShiftControlValue
   );
   Set(
        currentHEATNO,
        YourCurrentHeatNoControlValue
   );
   SubmitForm(Form2);
   ResetForm(Form2);    //optional
   NewForm(Form2),

Please click Accept as solution if my post helped you solve your issue. This will help others find it more readily. It also closes the item. If the content was useful in other ways, please consider giving it Thumbs Up.

[v-xida-msft]

Hi @ashleylinkewich ,

Do you use SubmitForm function to submit your form data (Form2)?

Could you please share a bit more about your data source? Is it a CDS Entity?

Based on the needs that you mentioned,  I think a variable could achieve your needs. According to the issue that you mentioned, I think there is something with the value you set as default value within the Operator ComboBox, Shift ComboBox and Machine CombBox.

In addition, you should not put your Set() formula within the OnSelect property of the "Submit" button along with the SubmitForm() function. Instead, you should put your Set formula within the OnSuccess property of the Edit form.

Please consider modify the formula within the OnSelect property of the "Submit" button to following:

If(
    And(
        (DateValue6.SelectedDate) = (DateValue5.SelectedDate),
        Value(HourValue5.Selected.Value) > Value(HourValue6.Selected.Value)
    ),
    SubmitForm(Form2),
    If(
        And(
            DateValue6.SelectedDate = DateValue5.SelectedDate,
            Value(HourValue5.Selected.Value) < Value(HourValue6.Selected.Value)
        ),
        Notify(
            "Finish time can't be before start time",
            NotificationType.Error
        ),
        If(
            And(
                DateValue5.SelectedDate > DateValue6.SelectedDate,
                Value(HourValue5.Selected.Value) < Value(HourValue6.Selected.Value)
            ),
            SubmitForm(Form2),
            If(
                And(
                    DateValue5.SelectedDate > DateValue6.SelectedDate,
                    Value(HourValue5.Selected.Value) > Value(HourValue6.Selected.Value)
                ),
                Notify(
                    "Shift can't be more than 24 hours",
                    NotificationType.Error
                ),
                If(
                    DateValue5.SelectedDate < DateValue6.SelectedDate,
                    Notify(
                        "Finish date can't be before start date",
                        NotificationType.Error
                    ),
                    If(
                        IsMatch(
                            (DataCardValue21.Text),
                            "\.",
                            MatchOptions.Contains
                        ),
                        SubmitForm(Form2),
                        Notify(
                            "Weight must be in tonnes",
                            NotificationType.Error
                        )
                    )
                )
            )
        )
    )
)

Note: Remove the Set(...) formula and NewForm(Form2) formula from above OnSelect formula

Set the OnSuccess property of the Form2 to following:

Set(
     currentOPERATOR,
     Form2.LastSubmit.Operator2
);
Set(
     currentMACHINE,
     Form2.LastSubmit.MachineLookup
);
Set(
     currentSHIFT,
     Form2.LastSubmit.Shift
);
Set(
     currentHEATNO,
     Form2.LastSubmit.HeatNumber
);
NewForm(Form2)

Set the DefaultSelectedItems property of the Operator ComboBox to following:

If(
   Form2.Mode = FormMode.New,
   currentOPERATOR,
   Parent.Default
)

Set the DefaultSelectedItems property of Machine ComboBox to following:

If(
   Form2.Mode = FormMode.New,
   currentMACHINE,
   Parent.Default
)

Set the DefaultSelectedItems property of the Shift ComboBox to following (Shift field is a Option Set type field in your CDS Entity😞

If(
   Form2.Mode = FormMode.New,
   [currentSHIFT],
   [Parent.Default]
)

Set the Default property of the Heat Number Text Input box to following:

If(
   Form2.Mode = FormMode.New,
   currentHEATNO,
   Parent.Default
)

Note: The When setting default value for lookup controls (operator, machine), option set (shift), please set value within the DefaultSelectedItems property rather than Default property.

Best regards,

[WarrenBelz]

Hi @ashleylinkewich ,

A couple of options here - please tag the one that best suits your needs.

[ashleylinkewich]

Hi Kris,

This seemed to work for the shift option set, but not for the operator/machine dropdowns. 

Could this be because they are a lookup field in my CDS entity? They lookup from another entity, that is. 

Thank you!! 

[v-xida-msft · Accepted solution]

Hi @ashleylinkewich ,

I think this issue may be related to currentOPERATOR variable and currentMACHINE variable. When saving ComboBox selected value into these two variables, these two variables could be stored with proper value.

As an fixed solution, please save the selected operator/machine ComboBox value into a variable in your "Submit" button OnSelect formula.

Please consider modify the formula within the OnSelect property of the "Submit" button to following:

Set(                     // Add formula here
    currentOPERATOR,
    OperatorComboBox.Selected
);
Set(                    // Add formula here
    currentMACHINE,
    MachineComboBox.Selected
);
If(
    And(
        (DateValue6.SelectedDate) = (DateValue5.SelectedDate),
        Value(HourValue5.Selected.Value) > Value(HourValue6.Selected.Value)
    ),
    SubmitForm(Form2),
    If(
        And(
            DateValue6.SelectedDate = DateValue5.SelectedDate,
            Value(HourValue5.Selected.Value) < Value(HourValue6.Selected.Value)
        ),
        Notify(
            "Finish time can't be before start time",
            NotificationType.Error
        ),
        If(
            And(
                DateValue5.SelectedDate > DateValue6.SelectedDate,
                Value(HourValue5.Selected.Value) < Value(HourValue6.Selected.Value)
            ),
            SubmitForm(Form2),
            If(
                And(
                    DateValue5.SelectedDate > DateValue6.SelectedDate,
                    Value(HourValue5.Selected.Value) > Value(HourValue6.Selected.Value)
                ),
                Notify(
                    "Shift can't be more than 24 hours",
                    NotificationType.Error
                ),
                If(
                    DateValue5.SelectedDate < DateValue6.SelectedDate,
                    Notify(
                        "Finish date can't be before start date",
                        NotificationType.Error
                    ),
                    If(
                        IsMatch(
                            (DataCardValue21.Text),
                            "\.",
                            MatchOptions.Contains
                        ),
                        SubmitForm(Form2),
                        Notify(
                            "Weight must be in tonnes",
                            NotificationType.Error
                        )
                    )
                )
            )
        )
    )
)

Note: Remove the Set(...) formula and NewForm(Form2) formula from above OnSelect formula

Set the OnSuccess property of the Form2 to following (modify formula as below):

Set(
     currentSHIFT,
     Form2.LastSubmit.Shift
);
Set(
     currentHEATNO,
     Form2.LastSubmit.HeatNumber
);
NewForm(Form2)

Set the DefaultSelectedItems property of the Operator ComboBox to following:

If(
   Form2.Mode = FormMode.New,
   currentOPERATOR,
   ThisItem.Operator2
)

Set the DefaultSelectedItems property of Machine ComboBox to following:

If(
   Form2.Mode = FormMode.New,
   currentMACHINE,
   ThisItem.MachineLookup
)

Set the DefaultSelectedItems property of the Shift ComboBox to following (Shift field is a Option Set type field in your CDS Entity)

If(
   Form2.Mode = FormMode.New,
   [currentSHIFT],
   [Parent.Default]
)

Set the Default property of the Heat Number Text Input box to following:

If(
   Form2.Mode = FormMode.New,
   currentHEATNO,
   Parent.Default
)

Note: The When setting default value for lookup controls (operator, machine), option set (shift), please set value within the DefaultSelectedItems property rather than Default property.

Please take a try above modified formula, check if the issue is fixed.

Best regards,