Searching key words across two fields

[Sofiyan]

Hello - I have tried multiple solutions but none have resulted in the desired output. 

I am searching for keywords in two fields ("Name" and "Description"). I have seen many posts using Search or Filter or custom formulas but without any success. Here is the breakdown of what I have tried and their outcome. Anything the community can add/provide clarity on?

Solution 1: Here I used filter but it does not like the || (OR operator). When I search for even a single word, no results populate.

With({kValue: SearchBar.Text}, Filter(Columns, kValue=Description || kValue=Name))

Solution 2: This should be intuitive and easy but nothing populates when I search.

Search(Columns, SearchBar.Text, "Description", "Name")

Solution 3: This came from a great post by @CalfordMath  but I am confused by his use of the "Results" field. Not sure what it refers to and what I should add from my own dataset to make this code complete.

Filter(
    Columns,
    IsBlank(
        Find(
            "0",
            Concat(
                Filter(
                    Split(
                        SearchBar.Text,
                        "," //or any delimiter.
                    ),
                    !IsBlank(Result)
                ),
                If(
                    TrimEnds(Result) in Name || TrimEnds (Result) in Description, // etc.
                    "1",
                    "0"
                )
            )
        )
    )
)

Solution 4: This solution works but only for value that start with the keyword. I am looking for values where keyword is found anywhere in the string.

Filter(Columns, StartsWith(Name, SearchBar.Text))

[CalfordMath]

Just covering the basic potential bugs:  Make sure the names of the data source and columns are indeed the same as the ones you reference in your code (data table named "Columns", with columns named "Name" and "Description").  But if you're getting results for a single search word, this likely isn't the problem.
One thought, the comma character can be the problem, if you copy and pasted it form my example.  Sometimes apostrophes and commas paste differently, as there are a few characters that represent them.  For example, I opened Notepad and typed an apostrophe, then opened Word and typed an apostrophe and copy and pasted it into notepad.  Here are the two side by side: '’  You can see they are different.  The problem could be that your delimiter comma in your code is not the same as the comma character you type in your SearchBar?  Long shot, but often coding bugs are something technical like this!

[Sofiyan]

@CalfordMath , so the comma works. As you can see in the screenshots below, by entering additional keywords, the search is further refined.

The issue I am having is when more then one keyword is entered, the result set only contains fields that have all the keywords, instead of returning fields that have any of the keywords. Any advice on how to update the code to achieve this effect? If you feel like you have exhausted your options, I completely understand. Thank you for your help so far.

Comma's are working screenshots:

Search is further refined when commas are used:

[CalfordMath · Accepted solution]

Oh! I'm sorry, I misunderstood what you wanted all along then.  The code is easily modified for this purpose. Actually, I included such an adaptation in my other post.  I'll paste my reply here too: 

The code searches for each keyword and builds a string of “0”s (word not found) and “1”s (word found) as it does this.  Example: If I searched for 3 keywords, and the string returned was “010” that would mean that only the 2nd keyword was found.  To have the search return only records that contain ALL three words, I would only want “111” cases, so the filter I used is to require “IsBlank” when I search for a zero.  Conversely, if ANY word found is favourable, I could simply search for a “1” in the string.  So I remove the “IsBlank” bracket, change my “Find 0” to a “Find 1” 

Here is a visual:

I've modified your code:

Filter(
    Columns,    
        Find(
            "1",
            Concat(
                Filter(
                    Split(
                        SearchBar.Text,
                        "," //or any delimiter.
                    ),
                    !IsBlank(ThisRecord.Value)
                ),
                If(
                    TrimEnds(ThisRecord.Value) in Name || TrimEnds (ThisRecord.Value) in Description, // etc.
                    "1",
                    "0"
                )
            )
        )>0
)

[Sofiyan]

That was it! very relieved to have found your solution to something which seems very complex to someone with limited knowledge on this app. this is awesome. Thank you, thank you, thank you.

Accepting it as the solution although honorable mention to @WarrenBelz for teaching us both the updated output for Split.