Setting the value of a global variable to the result of a with statement

[Katdragon]

Hi everyone,

If you've read some of my previous posts then you'll know I've created a Power App that keeps track of CPD points for people in my company (thanks to everyone who helped me!)

I've run into a bit of a problem though. I'm able to count the number of points for a particular user, but I just found out that there are restrictions on the number of points they can earn per type of activity they do. For example, they can get 1 CPD point for a webinar they attend, but they can only earn a maximum of 5 points per year. So if they attend seven webinars, they can still only get 5 points. Right now, my counter includes all of the session points they've accrued and not applied a restriction so if they've attended seven webinars it's showing 7 points.

This is the counter code that's currently sitting in the Text field of a label:

With(
    {
        webinarData: Filter(
            CPDtracker,
            User().FullName in Practitioner.DisplayName && CPDYear = "2023" && Format = "Webinar"
        )
    },
    Sum(
        webinarData,
        Points
    )
)

What I'd like to do is take the result of that calculation and put it in a variable to compare to a threshold value (ie, 5 points).

The logic will be:

If the result of the calculation <= threshold value, then set the global variable to the calculation value and pass it on to another screen that calculates the total number of points

Otherwise,

If the result of the calculation > threshold value then set the global variable to the threshold value and pass it on to another screen that calculates the total number of points.

My major issue is that I can't get the results of the current 'With' statement into a variable to compare to the threshold value.

I've set up the threshold values as global variables in the OnStart area of the App ie:

//Points threshold for Webinars is 5
Set (
    glblWebinarsThreshold,
    5
);

 For testing purposes I've used

//Test threshold for Webinars is 0
Set (
    glblTestThreshold,
    0
);

but for some reason I can't set up a variable to compare it to.

I've tried the following:

With(
    {
        webinarData: Filter(
            CPDtracker,
            User().FullName in Practitioner.DisplayName && CPDYear = "2023" && Format = "Webinar"
        )
    },
    Set(glblTestThreshold,Sum(
        webinarData,
        Points
    )
    )
)

which gives me the 'Behavior function in a non-behavior property' error

I'm probably doing something very stupid wrong - help please!

[poweractivate]

I think the issue you're facing could be because you try to use the Set function within a non-behavior property.

In Power Apps, behavior functions like Set should be used within a property that supports behavior, such as the OnSelect property of a button.

To set the global variable based on the condition you described, you can follow these steps:

1. Calculate the Webinar Points: First, calculate the sum of the webinar points in a context variable within a behavior property like OnSelect of a button.

2. Apply the Threshold: Next, compare the sum to the threshold, and set the global variable accordingly.

Here's the formula to perform these steps:

In the OnSelect property of a button, you can write:

With(
    {
        webinarData: Filter(
            CPDtracker,
            User().FullName in Practitioner.DisplayName && CPDYear = "2023" && Format = "Webinar"
        ),
        webinarSum: Sum(
            webinarData,
            Points
        )
    },
    Set(
        gloWebinarPoints,
        If(
            webinarSum <= glblWebinarsThreshold,
            webinarSum,
            glblWebinarsThreshold
        )
    )
)

This formula should calculate the sum of webinar points and then check if the sum is less than or equal to the threshold value (glblWebinarsThreshold). If it is, it sets the global variable gloWebinarPoints to the sum. If the sum is greater than the threshold value, it sets the global variable to the threshold value.

You can then use the global variable gloWebinarPoints on other screens to calculate the total number of points.

See if it helps @Katdragon 

[Katdragon]

Thanks so much, I'll give it a go!

I was wondering if it would be possible to do this without using a button since I just want the display to come up automatically (should I use the OnStart area of the app?)

[poweractivate]

@Katdragon 

Yes you have two options for moving this whole formula away from the button OnSelect and to a more appropriate place for your scenario.

Option #2 is generally much better than Option #1:

Option #1: OnVisible of first screen - You can move the formula to the first screen. However, if you have only one screen right now, you should create a second blank screen, and then toggle back and forth in the Power Apps Editor between the two screens so you can fire the OnVisible of the first screen successfully in the Power Apps Editor.

You would do this again in the Editor whenever you want to simulate starting the app again.

It may also be possible to do this from preview mode, but only if the screen is being changed from another screen to the first screen. It's often easiest to just toggle select between the other screen and the first screen again outside of Preview mode, when doing it this way.

Option #2: OnStart of the App - but if you do move your formula to the OnStart property of App you must remember to click on the ellipses to the right of the word App in Tree View (and the Tree view itself is on the left side of the Power Apps Editor), then click on Run OnStart to fire the OnStart and run the formula successfully. 

You must do this each time you want to run the OnStart formula again and test in the Editor as if running the app from the very beginning.

The OnStart property of App does not fire automatically at any time in Power Apps Editor or Preview mode in the Editor, it only fires usually in the live published app at the beginning on play of the app.

To test in the Editor as if playing the app from the beginning, but remaining in the Power Apps Editor, you must click the Run OnStart manually each time.

See if it helps @Katdragon 

[Katdragon]

@poweractivate thanks so much. I'll probably go with Option #2 then. 

I'm having a teeny tiny problem with the Sum code (I tried this before and it didn't work) since it's not recognising 'Points' as being a column from CPDtracker. 

Any thoughts?

Thanks!

[poweractivate]

@Katdragon You have Points initially in your original formula:

With(
    {
        webinarData: Filter(
            CPDtracker,
            User().FullName in Practitioner.DisplayName && CPDYear = "2023" && Format = "Webinar"
        )
    },
    Sum(
        webinarData,
        Points
    )
)

Was this working before? It would seem it should not work in your original formula either as you gave it. If so, check if Points is the correct name, or if it should be something else on your side.

Also check if the formula I gave for some reason works only in the OnSelect of Button , but not in OnStart? 

I think  it's probable your original formula with Points didn't work either, but I am not sure. It's possible it did. It may matter where you placed the formulas. For now just tell me if the original formula with Points works for some reason and not the new one for some reason. Are you still using the original formula since it was sitting in a Text property of a label as you mentioned before?

[Katdragon]

Hi @poweractivate ,

I created a new button to test my original code and got no errors. 

I then plugged your code into the button and got the errors. 

Edit: It also isn't recognising webinarData

I've attached a screenshot so you can see what I'm doing button-wise!

[poweractivate · Accepted solution]

@Katdragon 

Oh I know the issue, I have a mistake in my formula, the With must be nested again and I forgot to do that.
Try like this below:

With(
    {
        webinarData: Filter(
            CPDtracker,
            User().FullName in Practitioner.DisplayName && CPDYear = "2023" && Format = "Webinar"
        )
    },
    With(
        {
            webinarSum: Sum(
                webinarData,
                Points
            )
        },
        Set(
            gloWebinarPoints,
            If(
                webinarSum <= glblWebinarsThreshold,
                webinarSum,
                glblWebinarsThreshold
            )
        )
    )
)

See if it helps @Katdragon 

[Katdragon]

@poweractivate we have a winner with the code!

I'll give it a go on a new screen using the OnStart and let you know how things progress. 
I've accepted your answer with the new code.

Thanks again 🙂