Troubleshooting the Context Variable Types Are Incompatible Error

[ConnM]

Hello

I have made a classic mistake in following a tutorial that I don't quite understand.

I followed Matthew Devaney's excellent guide on building a timesheet

Make A Power Apps Timesheet App - Part 2 (matthewdevaney.com)

And it was working excellently last night. This morning I start it up and my screen is covered in red errors, mostly the visible properties saying "Incompatible Types for comparison. These types can't be compared: Error, Text" for this

If(
gblTimesheetCurrent.Status.Value="New",
DisplayMode.Edit,
DisplayMode.Disabled
)

Or "The function Isblank has some invalid arguements" For this

!IsBlank(gblTimesheetCurrent)

Of course is issue is with my gblTimesheetCurrent variable. I am getting "Incompatible type. We can't evaluate your formula because the context variable types are incompatible with the types of values in other places in your app" this morning, where yesterday I was getting none. It is beyond my current understanding to troubleshoot this myself.

The variable is defined in four places

1

// update the timesheet status to submitted
Set(
gblTimesheetCurrent,
Patch(
Timesheets,
gblTimesheetCurrent,
{Status: {Value: "Submitted"}}
)
);
// save the timesheet lines
Select(IconSave);

2 - No red squiggly lines

Set(
gblTimesheetCurrent,
ThisItem
);
ClearCollect(
colTimesheetLines,
Filter(
TimeTracker,
TimesheetID = gblTimesheetCurrent.ID
)
);
Clear(colDeleteTimesheetLines)

3

// create a new timesheet and store the result
Set(
gblTimesheetCurrent,
Patch(
Timesheets,
Defaults(Timesheets),
{

// set timesheet employee to current user
Employee: {
'@odata.type':"#Microsoft.Azure.Connectors.SharePoint.SPListExpandedUser",
Claims: $"i:0#.f|membership|{User().Email}",
Department: "",
DisplayName: User().FullName,
Email: User().Email,
JobTitle: "",
Picture: ""
},

// set start date to Saturday of the selected week
StartDate: DateAdd(dte_TimesheetWeek.SelectedDate,1-Weekday(dte_TimesheetWeek.SelectedDate,StartOfWeek.Saturday),TimeUnit.Days),

// set end date to Friday of the selected week
EndDate: DateAdd(dte_TimesheetWeek.SelectedDate,1-Weekday(dte_TimesheetWeek.SelectedDate,StartOfWeek.Friday)+7,TimeUnit.Days),

Status: {Value: "New"},
TotalHours: 0
}
)
);
// create the first timesheet line
ClearCollect(
colTimesheetLines,
Patch(
TimeTracker,
Defaults(TimeTracker),
{TimesheetID: gblTimesheetCurrent.ID}
)
);
// reset date picker to blank
Reset(dte_TimesheetWeek)

4 no red squiggly lines, but I swear it did earlier

Set(gblTimesheetCurrent, Blank());
Clear(colDeleteTimesheetLines);

If anyone can dig through this, and tell me where I went wrong it would be much appreciated

Conn

[ConnM]

I cleared the cache, which did not fix the issue
I then removed the semicolons that were at the very end of the code on points 1 and 4, which allowed the program to work. Still concerned the problem will reappear in the morning 

[ConnM]

Yes, it promptly broke again

[v-jefferni · Accepted solution]

Hi @ConnM ,

Could you please go and find the very first place this variable is set in your App? The issue is this variable includes a result record returned by Patch function, if no one has performed OnSelect on a button or icon, this variable will be error. If you can run the App normally, you can ignore this error. You can also try and add below formula into OnStart of App:

Set(gblTimesheetCurrent, Blank());

Best regards,

[ConnM]

Setting the variable in OnStart sorted it, thank you very much @v-jefferni 

[subsguts]

A different solution that I hope helps others save tons of time:

I had this error and none of the solutions I found anywhere would solve it.  Then by some miracle and hours I figured out what caused it.  I believe others have and will run into this and the error message makes it nearly impossible to figure out without this knowledge so I hope it helps others.

So I had a local variable inside a button defined as :

UpdateContext({lclSendMailTo: ""});

Then it was assigned 4 others times in the button as follows, depending on a variety of factors (note these were not like this, it was a large complicated function with lots switches, etc. and they were assigned in different parts of the button select code):

UpdateContext({lclSendMailTo: gblSelectedProvider.ProviderModifiedEmailTXT});

UpdateContext({lclSendMailTo: gblSelectedPosition.PositionModifiedBy});

UpdateContext({lclSendMailTo: gblSelectedLocation.ProviderPositionLocationModifiedEmailTXT});

UpdateContext({lclSendMailTo: gblSelectedPrivilege.ProviderPositionPrivilegeModifiedEmailTXT});

My code was working when I just had the first Updated Context of these 4, but when I added the other 3, everything stopped working and I got messages like the lclSendMailTo wasn't being used in my app to the awful "Incompatible type.  We can't evaulate your formula because the context variable types are incompatible with the types of values in other places in your app".

What this error message really means, is that you have used the same context variable and assigned it different types of values (at least one time and that's all it takes).  For example, you assigned it text to begin with, then you assigned it a number, then  you assigned it a record, etc.  As soon as you do the wrong assignment it will mark a lot of statements as being wrong (practically every statement), even though that first one is what is causing all the problems.  What makes it even harder to determine the offending statement you added is this error doesn't necessarily appear until after you've made all the changes.  Sometimes it even will seem like it's fixed until you run your code and then it will reappear.

In my case above the statement:

UpdateContext({lclSendMailTo: gblSelectedPosition.PositionModifiedBy}); 

refers to a Person, instead of an email that I thought.  As soon as I change this to:

UpdateContext({lclSendMailTo: gblSelectedLocation.ProviderPositionLocationModifiedEmailTXT});

ALL the errors disappeared because now I was only assigning the lclSendMailTo a variable of type Text.

In summary, if you get this awful message, go back and look at every place you have assigned the variable and see what type of assignment you are making because somewhere you are assigning it a different type.  You can even try commenting out one statement at a time to find the offender (of course you could have more than one, for example, if you had the variable assigned twice as a text and twice as a numeric, but that's probably less likely than my scenario where one wrong assignment brings your development to a screeching halt.

I hope this saves folks Hours and Hours of time! 🙂