Weekends excluding

[Lavanya11]

Hey folks, hope everyone doing Well.

In my leave application I used two date Pickers and a text label to show no of days that I wanted to take leave. In that text label assigned function to prepopulate the No of days chosen from date pickers.  So, what I want is that date pickers should exclude the 

Weekends and should not take past dates.

Hope explained clearly and expecting solution ASAP.

[Rajkumar_404]

Hi 

@Lavanya11 

In PowerApps, you can't directly disable weekends or past dates in the DatePicker control. However, you can use Reset function() and create a workaround to prevent users from selecting weekends or past dates.

You can show a warning message or reset the selected date if a user selects a weekend. To do this, you can use the OnChange property of the DatePicker.

DatePicker 1:

If(
Self.SelectedDate <= Today()  || Weekday(Self.SelectedDate) in [1, 7],
Notify( "Weekends are not allowed for leave. Please select a weekday.") 
&& Reset(Self)
)

DatePicker 2:

If(
    Self.SelectedDate <= DatePicker1.SelectedDate  || Weekday(Self.SelectedDate) in [1, 7],
    Notify( "Weekends are not allowed for leave. Please select a weekday.") &&
 Reset(Self)
)

Default Property of DatePicker 2 : 

DatePicker1.SelectedDate +1

Thanks!

If my response has been helpful in resolving your issue, I kindly request that you consider clicking "Accept as solution" and "giving it a thumbs up" as a token of appreciation.

[Chris-D]

Hi @Lavanya11 ,

The first issue, date validation.

I'm going to use DatePicker1 as your start date and DatePicker2 as your end date. First, try this setup to prevent invalid dates from being selected. 

//--- START DATE ---//
// set start date to next working day
DatePicker1.Default:
DateAdd( 
    Today(), 
    Index( 
        [1,1,1,1,3,2,1], 
        Weekday( Today(), StartOfWeek.Monday)
    ).Value, 
    TimeUnit.Days
)

// prevent past dates - reset the date picker to default value if date is in past, or it's after the end date
DatePicker1.OnChange:
If( 
    // Date is before tomorrow
    Self.SelectedDate < Today() +1

    // Date is after end date
    || Self.SelectedDate > DatePicker2.SelectedDate
    , 
    Reset( Self)
);

//--- END DATE ---//
// set start date to working day after the start date
DatePicker2.Default:
DateAdd( 
    DatePicker1.SelectedDate, 
    Index( 
        [1,1,1,1,3,2,1], 
        Weekday( DatePicker1.SelectedDate, StartOfWeek.Monday)
    ).Value, 
    TimeUnit.Days
)

// prevent dates before the start date
DatePicker2.OnChange:
If( 
    // Date is on or before start date
    Self.SelectedDate <= DatePicker1.SelectedDate, 
    Reset( Self)
);

Next, to calculate working days, add this code to a text label:

// Use With() to set up some input parameters
With({
    StartDate: DatePicker1.SelectedDate,
    EndDate: DatePicker2.SelectedDate
},
    With({
        // Make sure our dates are the right way around
        PastDate: Min( StartDate, EndDate),
        FutureDate: Max( StartDate, EndDate)
    },
        With({
            // Work out total days, add 1 to include the last day
            Days: DateDiff( PastDate, FutureDate) +1,

            // Work out how many working days in the first week and last week
            // This corrects for partial weeks in range
            WorkingDaysBefore: Max( 0, 8- Weekday( PastDate, StartOfWeek.Monday) -2),
            WorkingDaysAfter: Min( 5, Weekday( FutureDate, StartOfWeek.Monday))
        },
            With({
                // Int() removes numbers after the decimal point
                // This gives us the number of whole weeks, less the days we already counted
                Weeks: Int((Days -WorkingDaysBefore -WorkingDaysAfter) /7)
            },
                // The answer is the weekdays in whole weeks
                // Add on the weekdays in the partial weeks before and after
                With({
                    WorkingDays: (Weeks *5) +WorkingDaysBefore +WorkingDaysAfter
                },
                    $"{WorkingDays} working days"
                )
            )
        )
    )
)