check if record exists

[StanSaggi]

Hi, I would like to know if it is possible to check if more than one value in a row exists in a SharePoint list. I need to check this in a Power Apps, before I can save data into a database.

For example

Column 1, Column 2

Slot1       , 20/02/2024

Slot2       ,20/02/2024

Slot3       ,20/02/2024

Slot3       ,20/02/2024

So I need to check if Column 1 and Column 2 contain the values

Slot1 and 20/02/2024 are appearing together in the same row within a SharePoint list.

It should work like a SQL query:

select * from Test

where Column 1 = 'Slot1'

and Column 2 = '20/02/2024'

Thank you very much in advance.

[Amik]

@StanSaggi - for example, apply the below to the Text property of a Label:

!IsBlank(
    LookUp(
        'Your Data',
        Column1 = "Slot1" && Column2 = Date(
            2024,
            2,
            20
        )
    )
)

The above will return true if the combination exists. However, I suspect you need something dynamic, so it would help if you provided better context for what you're ultimately trying to do.

[StanSaggi]

Hi Imran, I'm trying to check if the record exists before I can enter the data into the SharePoint list. If the combination exists, then I should not add the data. If it does not exist, then I should add the data. The date column is actually a text column. Where can I show the error message if the combination data exists?. This is how I have changed your code: !IsBlank( LookUp( 'Reservations', Desk ID = DrpDwnFloorDeskNum.Selected.Title && ReservationDate = Text(BookingDateDatePicker.SelectedDate) ), Notify("This reference already exists", NotificationType.Error) ) It seems like it is not validating?.

[Amik · Accepted solution]

@StanSaggi - I think the below is what you're trying to do:

If(
    IsBlank(
        LookUp(
            Reservations,
            Title = DrpDwnFloorDeskNum.Selected.Title && ReservationDate = Text(BookingDateDatePicker.SelectedDate)
        )
    ),
    Patch(
        Reservations,
        Defaults(Reservations),
        {
            Title: DrpDwnFloorDeskNum.Selected.Title,
            ReservationDate: Text(BookingDateDatePicker.SelectedDate)
        }
    ),
    Notify(
        "This reference already exists",
        NotificationType.Error
    )
)

Note above I removed the NOT operator ( ! ) from the code. If we include the NOT operator, we just simply switch the around the Notify and Patch functions.

If(
    !IsBlank(
        LookUp(
            Reservations,
            Title = DrpDwnFloorDeskNum.Selected.Title && ReservationDate  = Text(BookingDateDatePicker.SelectedDate)
        )
    ),
    Notify(
        "This reference already exists",
        NotificationType.Error
    ),
    Patch(
        Reservations,
        Defaults(Reservations),
        {
            Title: DrpDwnFloorDeskNum.Selected.Title,
            ReservationDate: Text(BookingDateDatePicker.SelectedDate)
        }
    )
)

[StanSaggi]

Hi Imran, thank you very much for you help.