Extracting Date information to be used for creating folders.

[eyarea51]

Hello all I am new to power automate desktop.  and I need to create a very robust flow where I need to copy files from a computer.  Based on the month and year create the folders accordingly and move the files to those folders.  I am having trouble trying to figure out how to get the date information to parse out the month and year.

Please Point me in the right direction!

[Deenuji]

@eyarea51 

Could you please share some info how your file name looks like?

Share some screenshot if possible how your files are looks like in your folder

Thanks,
Deenuji Loganathan 👩‍💻
Automation Evangelist 🤖
Follow me on LinkedIn 👥

-------------------------------------------------------------------------------------------------------------
If I've helped solve your query, kindly mark my response as the solution ✔ and give it a thumbs up!👍 Your feedback supports future seekers 🚀

[eyarea51]

The File name would be WIN_20240626_11_35_30_Pro.jpg

[NathanAlvares24]

Hi @eyarea51 !

You can try this flow.

Code (just copy paste the code into your flow):

SET FolderPath TO $'''C:\\Users\\UserName\\Desktop\\Testing files'''
Folder.GetFiles Folder: FolderPath FileFilter: $'''WIN*''' IncludeSubfolders: False FailOnAccessDenied: True SortBy1: Folder.SortBy.NoSort SortDescending1: False SortBy2: Folder.SortBy.NoSort SortDescending2: False SortBy3: Folder.SortBy.NoSort SortDescending3: False Files=> Files
LOOP FOREACH File IN Files
    SET FileName TO File.NameWithoutExtension
    Text.SplitText.SplitWithDelimiter Text: FileName CustomDelimiter: $'''_''' IsRegEx: False Result=> TextFileList
    Text.ConvertTextToDateTime.ToDateTimeCustomFormat Text: TextFileList[1] CustomFormat: $'''yyyyMMdd''' DateTime=> DateFormatted
    Text.ConvertDateTimeToText.FromCustomDateTime DateTime: DateFormatted CustomFormat: $'''yyyy''' Result=> strYear
    Text.ConvertDateTimeToText.FromCustomDateTime DateTime: DateFormatted CustomFormat: $'''MMM''' Result=> strMonth
    IF (Folder.IfFolderExists.Exists Path: $'''%FolderPath%\\%strYear%''') THEN
        IF (Folder.IfFolderExists.DoesNotExist Path: $'''%FolderPath%\\%strYear%\\%strMonth%''') THEN
            Folder.Create FolderPath: $'''%FolderPath%\\%strYear%''' FolderName: strMonth Folder=> NewFolder
        END
    ELSE
        Folder.Create FolderPath: FolderPath FolderName: strYear Folder=> NewFolder
        Folder.Create FolderPath: $'''%FolderPath%\\%strYear%''' FolderName: strMonth Folder=> NewFolder
    END
    File.Move Files: File Destination: $'''%FolderPath%\\%strYear%\\%strMonth%''' IfFileExists: File.IfExists.DoNothing MovedFiles=> MovedFiles1
END

Before:

After:

So all you need to do is just copy your files into the Main Folder. Use Get files in folder action with filter as "WIN*" to get all files starting with that irrespective of extension. And it will do the work.

I hope this helps.

[Deenuji]

@eyarea51 

Please follow the below approach:

Before:

After:

Code:

Folder.GetFiles Folder: $'''C:\\Boot\\Images''' FileFilter: $'''*''' IncludeSubfolders: False FailOnAccessDenied: True SortBy1: Folder.SortBy.NoSort SortDescending1: False SortBy2: Folder.SortBy.NoSort SortDescending2: False SortBy3: Folder.SortBy.NoSort SortDescending3: False Files=> Files
SET Root_Folder TO $'''C:\\Boot\\Images'''
LOOP FOREACH CurrentItem IN Files
    SET FileName TO CurrentItem.Name
    @@copilotGeneratedAction: 'False'
Scripting.RunPowershellScript.RunPowershellScript Script: $'''# Filename
$filename = \"%FileName%\"

# Regex pattern to match and capture the year and month
$pattern = \'WIN_(\\d{4})(\\d{2})\\d{2}_\\d{2}_\\d{2}_\\d{2}\'

# Use regex to match and extract the year and month
if ($filename -match $pattern) {
    $year = $matches[1]
    $monthNumber = $matches[2]

    # Convert month number to month name
    $monthName = [CultureInfo]::CurrentCulture.DateTimeFormat.GetMonthName([int]$monthNumber)
    
    # Output the extracted year and month name
    Write-Output \"$year\"
    Write-Output \"$monthName\"
} else {
    Write-Output \"Filename format does not match the expected pattern.\"
}''' ScriptOutput=> PowershellOutput
    IF NotContains(PowershellOutput, $'''Filename format''', True) THEN
        Text.SplitText.Split Text: PowershellOutput StandardDelimiter: Text.StandardDelimiter.NewLine DelimiterTimes: 1 Result=> TextList
        SET Str_Year TO TextList[0]
        SET Str_Month TO TextList[1]
        IF (Folder.IfFolderExists.DoesNotExist Path: $'''%Root_Folder%\\%Str_Year%''') THEN
            Folder.Create FolderPath: Root_Folder FolderName: Str_Year Folder=> NewFolder
        END
        IF (Folder.IfFolderExists.DoesNotExist Path: $'''%Root_Folder%\\%Str_Year%\\%Str_Month%''') THEN
            Folder.Create FolderPath: $'''%Root_Folder%\\%Str_Year%''' FolderName: Str_Month Folder=> NewFolder
        END
        File.Move Files: CurrentItem.FullName Destination: $'''%Root_Folder%\\%Str_Year%\\%Str_Month%''' IfFileExists: File.IfExists.DoNothing MovedFiles=> MovedFiles
    END
END

Please adjust the configuration of the folders specified in the variable to suit your requirements.

How to copy/paste the above code into your power automate desktop?

Thanks,
Deenuji Loganathan 👩‍💻
Automation Evangelist 🤖
Follow me on LinkedIn 👥

-------------------------------------------------------------------------------------------------------------
If I've helped solve your query, kindly mark my response as the solution ✔ and give it a thumbs up!👍 Your feedback supports future seekers 🚀

[eyarea51]

Thank you for the information.

I do like to create the flow to help me learn.  

I did run into an issue as I am creating and watching the data.

the DateFormated is not getting the rite data, the convert text to datetime does not seem to gett he right part of the file name.  see my screenshot

[eyarea51]

I have Found My Mistake in the line.

Now I need to efficiently rename and move or Move and rename the file.

[NathanAlvares24]

Hi @eyarea51 !

What does your "TextFileList" look like?

Mine is this:

Hence I used TextFileList[1] since that has the format of date as yyyyMMdd

And I used the one marked in red as this is the required information for extraction.

Can you show screenshot what your "TextFileList" shows like? I can help in the extraction of the date.

[NathanAlvares24]

Hi @eyarea51 !

Do you need help in the part where you need to move and rename i.e. after the files have been moved to their locations? Any particular format it requires? I would gladly assist. If yes, do provide some more info in that case.

[eyarea51]

I added another get files folder after the rename so the move would work.    here is the code is theis the best way to do this?  

FUNCTION Main_copy GLOBAL
SET FolderPath TO $'''\\\\XXXXXXXX\\Users\\XXXXX\\Pictures\\Camera Roll'''
SET FolderPath2 TO $'''C:\\Workspace'''
Folder.GetFiles Folder: FolderPath FileFilter: $'''WIN*''' IncludeSubfolders: False FailOnAccessDenied: True SortBy1: Folder.SortBy.NoSort SortDescending1: False SortBy2: Folder.SortBy.NoSort SortDescending2: False SortBy3: Folder.SortBy.NoSort SortDescending3: False Files=> Files
LOOP FOREACH File IN Files
SET FileName TO File.NameWithoutExtension
Text.SplitText.SplitWithDelimiter Text: FileName CustomDelimiter: $'''_''' IsRegEx: False Result=> TextFileList
Text.ConvertTextToDateTime.ToDateTimeCustomFormat Text: TextFileList[1] CustomFormat: $'''yyyyMMdd''' DateTime=> DateFormatted
Text.ConvertDateTimeToText.FromCustomDateTime DateTime: DateFormatted CustomFormat: $'''yyyy''' Result=> strYear
Text.ConvertDateTimeToText.FromCustomDateTime DateTime: DateFormatted CustomFormat: $'''MMM''' Result=> strMonth
IF (Folder.IfFolderExists.Exists Path: $'''%FolderPath2%\\%strYear%''') THEN
IF (Folder.IfFolderExists.DoesNotExist Path: $'''%FolderPath2%\\%strYear%\\%strMonth%''') THEN
Folder.Create FolderPath: $'''%FolderPath2%\\%strYear%''' FolderName: strMonth Folder=> NewFolder
END
ELSE
Folder.Create FolderPath: FolderPath2 FolderName: strYear Folder=> NewFolder
Folder.Create FolderPath: $'''%FolderPath2%\\%strYear%''' FolderName: strMonth Folder=> NewFolder
END
File.RenameFiles.RenameReplaceText Files: File TextToReplace: $'''WIN''' ReplaceWith: $'''REG1''' IfFileExists: File.IfExists.DoNothing RenamedFiles=> RenamedFiles
Folder.GetFiles Folder: FolderPath FileFilter: $'''REG1*''' IncludeSubfolders: False FailOnAccessDenied: True SortBy1: Folder.SortBy.NoSort SortDescending1: False SortBy2: Folder.SortBy.NoSort SortDescending2: False SortBy3: Folder.SortBy.NoSort SortDescending3: False Files=> Files2
File.Move Files: Files2 Destination: $'''%FolderPath2%\\%strYear%\\%strMonth%''' IfFileExists: File.IfExists.DoNothing MovedFiles=> MovedFiles1
END
END FUNCTION

[Deenuji]

@eyarea51 

I have proposed a similar method to what you described above, but my process involves using a PowerShell script to output the year and month, then it creates a folder for them and moves the files into it.

Thanks,
Deenuji Loganathan 👩‍💻
Automation Evangelist 🤖
Follow me on LinkedIn 👥

-------------------------------------------------------------------------------------------------------------
If I've helped solve your query, kindly mark my response as the solution ✔ and give it a thumbs up!👍 Your feedback supports future seekers 🚀

[NathanAlvares24]

Hi @eyarea51 !

Let me guess what you are trying to achieve in this code:

Let's say this is my main folder where I got all those files starting with WIN like below:

Then I guess what you are trying to do is to store the month and year folders in another directory (folder), right? So as to make this main folder empty for any new files again. So the new folder will look like:

Is it?

If yes, I have modified the code as shown below:

In the Move files action, use the variable produced by Rename files action. It will be a list. So to access it, just use the first index of the list i.e. 0. So it will be: %RenamedFile[0]%

So you don't have to use another Get files in folder action. Just simply use the variables from the Create folder actions. You can rename it however you wish and then use that variable into the Move files action.

Code:

SET FolderPath TO $'''C:\\Users\\UserName\\Desktop\\Testing files'''
SET FolderPath2 TO $'''C:\\Users\\UserName\\Desktop\\Shifted files'''
Folder.GetFiles Folder: FolderPath FileFilter: $'''WIN*''' IncludeSubfolders: False FailOnAccessDenied: True SortBy1: Folder.SortBy.NoSort SortDescending1: False SortBy2: Folder.SortBy.NoSort SortDescending2: False SortBy3: Folder.SortBy.NoSort SortDescending3: False Files=> Files
LOOP FOREACH File IN Files
    SET FileName TO File.NameWithoutExtension
    Text.SplitText.SplitWithDelimiter Text: FileName CustomDelimiter: $'''_''' IsRegEx: False Result=> TextFileList
    Text.ConvertTextToDateTime.ToDateTimeCustomFormat Text: TextFileList[1] CustomFormat: $'''yyyyMMdd''' DateTime=> DateFormatted
    Text.ConvertDateTimeToText.FromCustomDateTime DateTime: DateFormatted CustomFormat: $'''yyyy''' Result=> strYear
    Text.ConvertDateTimeToText.FromCustomDateTime DateTime: DateFormatted CustomFormat: $'''MMM''' Result=> strMonth
    IF (Folder.IfFolderExists.Exists Path: $'''%FolderPath2%\\%strYear%''') THEN
        IF (Folder.IfFolderExists.DoesNotExist Path: $'''%FolderPath2%\\%strYear%\\%strMonth%''') THEN
            Folder.Create FolderPath: $'''%FolderPath2%\\%strYear%''' FolderName: strMonth Folder=> MonthFolder
        ELSE
            SET MonthFolder TO $'''%FolderPath2%\\%strYear%\\%strMonth%'''
        END
    ELSE
        Folder.Create FolderPath: FolderPath2 FolderName: strYear Folder=> YearFolder
        Folder.Create FolderPath: $'''%FolderPath2%\\%strYear%''' FolderName: strMonth Folder=> MonthFolder
    END
    File.RenameFiles.RenameReplaceText Files: File TextToReplace: $'''WIN''' ReplaceWith: $'''REG1''' IfFileExists: File.IfExists.DoNothing RenamedFiles=> RenamedFile
    File.Move Files: RenamedFile[0] Destination: MonthFolder IfFileExists: File.IfExists.DoNothing MovedFiles=> MovedFiles1
END

I hope this helps.

[eyarea51]

the process I am achieving is to copy the camera roll pictures and move them to A NAS but before doing so I need to rename them and sort them by month and year (maybe by day not sure what we want to do) before doing so.

The Code looks good, thank you!  I have to say in my older years, I have to get back to my college years where I was learning basic programing.  learning automate is bringing back memories.

[NathanAlvares24]

That's awesome to hear, @eyarea51 ! I'm actually learning a lot from this community too. If you have any more questions or need further help, feel free to ask. Happy to assist!

If I have helped solve your issue, please mark my response as the solution. It will make it easier for future learners to find similar topics.